* [FFmpeg-devel] [PATCH 1/2] lavc/ac3dsp: R-V V sum_square_butterfly_int32
@ 2024-04-29 19:21 Rémi Denis-Courmont
2024-04-29 19:21 ` [FFmpeg-devel] [PATCH 2/2] lavc/ac3dsp: R-V V sum_square_butterfly_float Rémi Denis-Courmont
2024-05-01 6:40 ` [FFmpeg-devel] [PATCH 3/3] lavc/ac3dsp: R-V V min_exponents Rémi Denis-Courmont
0 siblings, 2 replies; 3+ messages in thread
From: Rémi Denis-Courmont @ 2024-04-29 19:21 UTC (permalink / raw)
To: ffmpeg-devel
ac3_sum_square_bufferfly_int32_c: 61.0
ac3_sum_square_bufferfly_int32_rvv_i64: 14.7
---
libavcodec/riscv/ac3dsp_init.c | 6 +++++
libavcodec/riscv/ac3dsp_rvv.S | 41 ++++++++++++++++++++++++++++++++++
2 files changed, 47 insertions(+)
diff --git a/libavcodec/riscv/ac3dsp_init.c b/libavcodec/riscv/ac3dsp_init.c
index b9e14d56ca..be5e153fac 100644
--- a/libavcodec/riscv/ac3dsp_init.c
+++ b/libavcodec/riscv/ac3dsp_init.c
@@ -28,6 +28,8 @@
void ff_extract_exponents_rvb(uint8_t *exp, int32_t *coef, int nb_coefs);
void ff_float_to_fixed24_rvv(int32_t *dst, const float *src, size_t len);
+void ff_sum_square_butterfly_int32_rvv(int64_t *, const int32_t *,
+ const int32_t *, int);
av_cold void ff_ac3dsp_init_riscv(AC3DSPContext *c)
{
@@ -39,6 +41,10 @@ av_cold void ff_ac3dsp_init_riscv(AC3DSPContext *c)
c->extract_exponents = ff_extract_exponents_rvb;
if (flags & AV_CPU_FLAG_RVV_F32)
c->float_to_fixed24 = ff_float_to_fixed24_rvv;
+# if __riscv_xlen >= 64
+ if (flags & AV_CPU_FLAG_RVV_I64)
+ c->sum_square_butterfly_int32 = ff_sum_square_butterfly_int32_rvv;
+# endif
}
#endif
}
diff --git a/libavcodec/riscv/ac3dsp_rvv.S b/libavcodec/riscv/ac3dsp_rvv.S
index b8d32c4677..dd0b4cd797 100644
--- a/libavcodec/riscv/ac3dsp_rvv.S
+++ b/libavcodec/riscv/ac3dsp_rvv.S
@@ -37,3 +37,44 @@ func ff_float_to_fixed24_rvv, zve32f
ret
endfunc
+
+#if __riscv_xlen >= 64
+func ff_sum_square_butterfly_int32_rvv, zve64x
+ vsetvli t0, zero, e64, m8, ta, ma
+ vmv.v.x v0, zero
+ vmv.v.x v8, zero
+1:
+ vsetvli t0, a3, e32, m2, tu, ma
+ vle32.v v16, (a1)
+ sub a3, a3, t0
+ vle32.v v20, (a2)
+ sh2add a1, t0, a1
+ vadd.vv v24, v16, v20
+ sh2add a2, t0, a2
+ vsub.vv v28, v16, v20
+ vwmacc.vv v0, v16, v16
+ vwmacc.vv v4, v20, v20
+ vwmacc.vv v8, v24, v24
+ vwmacc.vv v12, v28, v28
+ bnez a3, 1b
+
+ vsetvli t0, zero, e64, m4, ta, ma
+ vmv.s.x v16, zero
+ vmv.s.x v17, zero
+ vredsum.vs v16, v0, v16
+ vmv.s.x v18, zero
+ vredsum.vs v17, v4, v17
+ vmv.s.x v19, zero
+ vredsum.vs v18, v8, v18
+ vmv.x.s t0, v16
+ vredsum.vs v19, v12, v19
+ vmv.x.s t1, v17
+ sd t0, (a0)
+ vmv.x.s t2, v18
+ sd t1, 8(a0)
+ vmv.x.s t3, v19
+ sd t2, 16(a0)
+ sd t3, 24(a0)
+ ret
+endfunc
+#endif
--
2.43.0
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
^ permalink raw reply [flat|nested] 3+ messages in thread
* [FFmpeg-devel] [PATCH 2/2] lavc/ac3dsp: R-V V sum_square_butterfly_float
2024-04-29 19:21 [FFmpeg-devel] [PATCH 1/2] lavc/ac3dsp: R-V V sum_square_butterfly_int32 Rémi Denis-Courmont
@ 2024-04-29 19:21 ` Rémi Denis-Courmont
2024-05-01 6:40 ` [FFmpeg-devel] [PATCH 3/3] lavc/ac3dsp: R-V V min_exponents Rémi Denis-Courmont
1 sibling, 0 replies; 3+ messages in thread
From: Rémi Denis-Courmont @ 2024-04-29 19:21 UTC (permalink / raw)
To: ffmpeg-devel
As we do not need to widen accumulators to 64 bits, we effectively get
double capacity for unrolling compared to the integer function. This
explains the slightly better performance gains.
ac3_sum_square_bufferfly_float_c: 65.2
ac3_sum_square_bufferfly_float_rvv_f32: 12.2
---
libavcodec/riscv/ac3dsp_init.c | 6 +++++-
libavcodec/riscv/ac3dsp_rvv.S | 39 ++++++++++++++++++++++++++++++++++
2 files changed, 44 insertions(+), 1 deletion(-)
diff --git a/libavcodec/riscv/ac3dsp_init.c b/libavcodec/riscv/ac3dsp_init.c
index be5e153fac..e120aa2dce 100644
--- a/libavcodec/riscv/ac3dsp_init.c
+++ b/libavcodec/riscv/ac3dsp_init.c
@@ -30,6 +30,8 @@ void ff_extract_exponents_rvb(uint8_t *exp, int32_t *coef, int nb_coefs);
void ff_float_to_fixed24_rvv(int32_t *dst, const float *src, size_t len);
void ff_sum_square_butterfly_int32_rvv(int64_t *, const int32_t *,
const int32_t *, int);
+void ff_sum_square_butterfly_float_rvv(float *, const float *,
+ const float *, int);
av_cold void ff_ac3dsp_init_riscv(AC3DSPContext *c)
{
@@ -39,8 +41,10 @@ av_cold void ff_ac3dsp_init_riscv(AC3DSPContext *c)
if (flags & AV_CPU_FLAG_RVB_ADDR) {
if (flags & AV_CPU_FLAG_RVB_BASIC)
c->extract_exponents = ff_extract_exponents_rvb;
- if (flags & AV_CPU_FLAG_RVV_F32)
+ if (flags & AV_CPU_FLAG_RVV_F32) {
c->float_to_fixed24 = ff_float_to_fixed24_rvv;
+ c->sum_square_butterfly_float = ff_sum_square_butterfly_float_rvv;
+ }
# if __riscv_xlen >= 64
if (flags & AV_CPU_FLAG_RVV_I64)
c->sum_square_butterfly_int32 = ff_sum_square_butterfly_int32_rvv;
diff --git a/libavcodec/riscv/ac3dsp_rvv.S b/libavcodec/riscv/ac3dsp_rvv.S
index dd0b4cd797..397e000ab0 100644
--- a/libavcodec/riscv/ac3dsp_rvv.S
+++ b/libavcodec/riscv/ac3dsp_rvv.S
@@ -78,3 +78,42 @@ func ff_sum_square_butterfly_int32_rvv, zve64x
ret
endfunc
#endif
+
+func ff_sum_square_butterfly_float_rvv, zve32f
+ vsetvli t0, zero, e32, m8, ta, ma
+ vmv.v.x v0, zero
+ vmv.v.x v8, zero
+1:
+ vsetvli t0, a3, e32, m4, tu, ma
+ vle32.v v16, (a1)
+ sub a3, a3, t0
+ vle32.v v20, (a2)
+ sh2add a1, t0, a1
+ vfadd.vv v24, v16, v20
+ sh2add a2, t0, a2
+ vfsub.vv v28, v16, v20
+ vfmacc.vv v0, v16, v16
+ vfmacc.vv v4, v20, v20
+ vfmacc.vv v8, v24, v24
+ vfmacc.vv v12, v28, v28
+ bnez a3, 1b
+
+ vsetvli t0, zero, e32, m4, ta, ma
+ vmv.s.x v16, zero
+ vmv.s.x v17, zero
+ vfredsum.vs v16, v0, v16
+ vmv.s.x v18, zero
+ vfredsum.vs v17, v4, v17
+ vmv.s.x v19, zero
+ vfredsum.vs v18, v8, v18
+ vfmv.f.s ft0, v16
+ vfredsum.vs v19, v12, v19
+ vfmv.f.s ft1, v17
+ fsw ft0, (a0)
+ vfmv.f.s ft2, v18
+ fsw ft1, 4(a0)
+ vfmv.f.s ft3, v19
+ fsw ft2, 8(a0)
+ fsw ft3, 12(a0)
+ ret
+endfunc
--
2.43.0
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
^ permalink raw reply [flat|nested] 3+ messages in thread
* [FFmpeg-devel] [PATCH 3/3] lavc/ac3dsp: R-V V min_exponents
2024-04-29 19:21 [FFmpeg-devel] [PATCH 1/2] lavc/ac3dsp: R-V V sum_square_butterfly_int32 Rémi Denis-Courmont
2024-04-29 19:21 ` [FFmpeg-devel] [PATCH 2/2] lavc/ac3dsp: R-V V sum_square_butterfly_float Rémi Denis-Courmont
@ 2024-05-01 6:40 ` Rémi Denis-Courmont
1 sibling, 0 replies; 3+ messages in thread
From: Rémi Denis-Courmont @ 2024-05-01 6:40 UTC (permalink / raw)
To: ffmpeg-devel
T-Head C908:
ac3_exponent_min_reuse0_c: 7.5
ac3_exponent_min_reuse0_rvv_i32: 7.5
ac3_exponent_min_reuse1_c: 1820.7
ac3_exponent_min_reuse1_rvv_i32: 102.5
ac3_exponent_min_reuse2_c: 3088.5
ac3_exponent_min_reuse2_rvv_i32: 138.7
ac3_exponent_min_reuse3_c: 5073.7
ac3_exponent_min_reuse3_rvv_i32: 174.7
ac3_exponent_min_reuse4_c: 4624.2
ac3_exponent_min_reuse4_rvv_i32: 204.2
ac3_exponent_min_reuse5_c: 5138.7
ac3_exponent_min_reuse5_rvv_i32: 238.0
---
libavcodec/riscv/ac3dsp_init.c | 4 ++++
libavcodec/riscv/ac3dsp_rvv.S | 22 ++++++++++++++++++++++
2 files changed, 26 insertions(+)
diff --git a/libavcodec/riscv/ac3dsp_init.c b/libavcodec/riscv/ac3dsp_init.c
index e120aa2dce..c7c375273d 100644
--- a/libavcodec/riscv/ac3dsp_init.c
+++ b/libavcodec/riscv/ac3dsp_init.c
@@ -26,6 +26,7 @@
#include "libavutil/cpu.h"
#include "libavcodec/ac3dsp.h"
+void ff_ac3_exponent_min_rvv(uint8_t *exp, int, int);
void ff_extract_exponents_rvb(uint8_t *exp, int32_t *coef, int nb_coefs);
void ff_float_to_fixed24_rvv(int32_t *dst, const float *src, size_t len);
void ff_sum_square_butterfly_int32_rvv(int64_t *, const int32_t *,
@@ -38,6 +39,9 @@ av_cold void ff_ac3dsp_init_riscv(AC3DSPContext *c)
#if HAVE_RV
int flags = av_get_cpu_flags();
+ if (flags & AV_CPU_FLAG_RVV_I32)
+ c->ac3_exponent_min = ff_ac3_exponent_min_rvv;
+
if (flags & AV_CPU_FLAG_RVB_ADDR) {
if (flags & AV_CPU_FLAG_RVB_BASIC)
c->extract_exponents = ff_extract_exponents_rvb;
diff --git a/libavcodec/riscv/ac3dsp_rvv.S b/libavcodec/riscv/ac3dsp_rvv.S
index 397e000ab0..1b5f67a9ec 100644
--- a/libavcodec/riscv/ac3dsp_rvv.S
+++ b/libavcodec/riscv/ac3dsp_rvv.S
@@ -21,6 +21,28 @@
#include "config.h"
#include "libavutil/riscv/asm.S"
+func ff_ac3_exponent_min_rvv, zve32x
+ beqz a1, 3f
+1:
+ vsetvli t2, a2, e8, m8, ta, ma
+ vle8.v v8, (a0)
+ addi t0, a0, 256
+ sub a2, a2, t2
+ mv t1, a1
+2:
+ vle8.v v16, (t0)
+ addi t1, t1, -1
+ vminu.vv v8, v8, v16
+ addi t0, t0, 256
+ bnez t1, 2b
+
+ vse8.v v8, (a0)
+ add a0, a0, t2
+ bnez a2, 1b
+3:
+ ret
+endfunc
+
func ff_float_to_fixed24_rvv, zve32f
li t1, 1 << 24
fcvt.s.w f0, t1
--
2.43.0
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2024-05-01 6:40 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2024-04-29 19:21 [FFmpeg-devel] [PATCH 1/2] lavc/ac3dsp: R-V V sum_square_butterfly_int32 Rémi Denis-Courmont
2024-04-29 19:21 ` [FFmpeg-devel] [PATCH 2/2] lavc/ac3dsp: R-V V sum_square_butterfly_float Rémi Denis-Courmont
2024-05-01 6:40 ` [FFmpeg-devel] [PATCH 3/3] lavc/ac3dsp: R-V V min_exponents Rémi Denis-Courmont
Git Inbox Mirror of the ffmpeg-devel mailing list - see https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
This inbox may be cloned and mirrored by anyone:
git clone --mirror https://master.gitmailbox.com/ffmpegdev/0 ffmpegdev/git/0.git
# If you have public-inbox 1.1+ installed, you may
# initialize and index your mirror using the following commands:
public-inbox-init -V2 ffmpegdev ffmpegdev/ https://master.gitmailbox.com/ffmpegdev \
ffmpegdev@gitmailbox.com
public-inbox-index ffmpegdev
Example config snippet for mirrors.
AGPL code for this site: git clone https://public-inbox.org/public-inbox.git