From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <ffmpeg-devel-bounces@ffmpeg.org>
Received: from ffbox0-bg.mplayerhq.hu (ffbox0-bg.ffmpeg.org [79.124.17.100])
by master.gitmailbox.com (Postfix) with ESMTPS id EF7A04DA94
for <ffmpegdev@gitmailbox.com>; Tue, 22 Apr 2025 16:31:38 +0000 (UTC)
Received: from [127.0.1.1] (localhost [127.0.0.1])
by ffbox0-bg.mplayerhq.hu (Postfix) with ESMTP id 3AA7B687D6B;
Tue, 22 Apr 2025 19:31:34 +0300 (EEST)
Received: from out162-62-57-49.mail.qq.com (out162-62-57-49.mail.qq.com
[162.62.57.49])
by ffbox0-bg.mplayerhq.hu (Postfix) with ESMTPS id EC3FC687BC4
for <ffmpeg-devel@ffmpeg.org>; Tue, 22 Apr 2025 19:31:26 +0300 (EEST)
DKIM-Signature: v=1; a=rsa-sha256; c=relaxed/relaxed; d=foxmail.com;
s=s201512; t=1745339477;
bh=ozOUYOo65+TU8xNmE2tXXTjFYMRe53odeSLwVMsZMrc=;
h=From:To:Cc:Subject:Date;
b=adtqd2BBIwlt+LWhMp4zFcAiyk6Hx9X3DksBN3EFKCp0Nr28XE2X7uEjS4ou/kOYn
5fJFh5YAd2Gim1eey/e5+ehCYcO4aM9IBxpdwsLXMWLxUJWROcKVExVqWqCBfnV+1q
XqvkxhLKjQsZURV1Bv5xCN+yI+iwmmNLGp+YdS9w=
Received: from ZHILIZHAO-MB1.tencent.com
([240e:3b7:3270:16e0:8548:623e:40e7:2a55])
by newxmesmtplogicsvrszc11-0.qq.com (NewEsmtp) with SMTP
id 7D01B63C; Wed, 23 Apr 2025 00:31:16 +0800
X-QQ-mid: xmsmtpt1745339476tu87raaao
Message-ID: <tencent_E595C1A91CCEAE4550D30CC85533ECF37005@qq.com>
X-QQ-XMAILINFO: NDgMZBR9sMmavrxwm4z27FwGDwcYftdKIt311jbcVJu6HfG5xaqkbOunzvpSIX
IbScCCIUBl2crulh3EilukkzUqVj3uOsNkxfD7br0NMUq3iNV8s6JHgc4aMw6+cUYqBosWAGh92t
dpH8qONU7NceTdUHhxo5hzvCRV/RushsFupVby2Lcvvhj8EN7PpVZbowJlGzfOGEToeG8AG9cm2o
G8xwiBp5hL8Yojv7gQfLkHvrTA4iPpygZGknVPEZX76oVtqSbCVsboFfYuh1tIDohR+o3p3w9M8x
u84KbodOP6eTO+3QiQMwPVrvCqzNbgcUh2OpWMnn+szneLNlkG16O6iufXQ3sEQaZjbiZFRtnXfj
lAqXRTs7dF2RbxxDN30l50VaBc5TDNgGgou1PD+wgMTVRfovmly9tSX92Up3JyD5MPi9cxMOHYCn
a+9nzyyfLpJmCz1Nd99mv0lFlYe+qeEnViGBpJZ8zRaFfeIoP49UM2tzXwglLIAYiwIgbBUYEhf7
DdLMqtwdXvAnQ8SstcCduPdBQh2kE4kh8VSXREgkTKnh+S6hyvfe90HdXbtmXG6BjzB5GS87ijsh
LdOUTE+F9u+Fa72+iCeJ2x795yZkCSO2MYYY1lGLXZXfNHiuC53Q6KrEQICWeBeJ+2ecumOQIpIc
ZZku1wHShdiallbhq3818LcUM+2XTdEKx0hqONyA9cd+q6OpxZ81fWTFg/oWqteNXzfCmKJ/3uZh
pGrayzoGaoGfvfaeIDgiVYnfpSxWxmwgRC1ka53AzMHbj4h6I4Dxa60u/pBujfZ1ZgdSitU9YwFS
/3NCLy94gSDlvNoiVF4s1aQI9Ro3gG36GNCkCdxVqUOPgR4L9X2FTPRXzEjR6zlILX8pzwRQYuEw
6YBQoYknEZco57rhMsqlH+Q96x45EXug4SKwiawbYWL9xwB78SoXCaHFeJkV82C5/rbJMApoeeWW
vcvsgyjYhFxAamhBKUVKFNnG9an52zsB526HnOqhuHs1/Q8Dha4Q==
X-QQ-XMRINFO: MSVp+SPm3vtS1Vd6Y4Mggwc=
From: Zhao Zhili <quinkblack-at-foxmail.com@ffmpeg.org>
To: ffmpeg-devel@ffmpeg.org
Date: Wed, 23 Apr 2025 00:31:11 +0800
X-OQ-MSGID: <20250422163111.84905-1-quinkblack@foxmail.com>
X-Mailer: git-send-email 2.46.0
MIME-Version: 1.0
Subject: [FFmpeg-devel] [PATCH] aarch64/h26x: Add put_hevc_pel_bi_w_pixels
X-BeenThere: ffmpeg-devel@ffmpeg.org
X-Mailman-Version: 2.1.29
Precedence: list
List-Id: FFmpeg development discussions and patches <ffmpeg-devel.ffmpeg.org>
List-Unsubscribe: <https://ffmpeg.org/mailman/options/ffmpeg-devel>,
<mailto:ffmpeg-devel-request@ffmpeg.org?subject=unsubscribe>
List-Archive: <https://ffmpeg.org/pipermail/ffmpeg-devel>
List-Post: <mailto:ffmpeg-devel@ffmpeg.org>
List-Help: <mailto:ffmpeg-devel-request@ffmpeg.org?subject=help>
List-Subscribe: <https://ffmpeg.org/mailman/listinfo/ffmpeg-devel>,
<mailto:ffmpeg-devel-request@ffmpeg.org?subject=subscribe>
Reply-To: FFmpeg development discussions and patches <ffmpeg-devel@ffmpeg.org>
Cc: Zhao Zhili <zhilizhao@tencent.com>
Content-Type: text/plain; charset="us-ascii"
Content-Transfer-Encoding: 7bit
Errors-To: ffmpeg-devel-bounces@ffmpeg.org
Sender: "ffmpeg-devel" <ffmpeg-devel-bounces@ffmpeg.org>
Archived-At: <https://master.gitmailbox.com/ffmpegdev/tencent_E595C1A91CCEAE4550D30CC85533ECF37005@qq.com/>
List-Archive: <https://master.gitmailbox.com/ffmpegdev/>
List-Post: <mailto:ffmpegdev@gitmailbox.com>
From: Zhao Zhili <zhilizhao@tencent.com>
On rpi5 (A76):
put_hevc_pel_bi_w_pixels4_8_c: 90.0 ( 1.00x)
put_hevc_pel_bi_w_pixels4_8_neon: 34.1 ( 2.64x)
put_hevc_pel_bi_w_pixels6_8_c: 188.3 ( 1.00x)
put_hevc_pel_bi_w_pixels6_8_neon: 73.5 ( 2.56x)
put_hevc_pel_bi_w_pixels8_8_c: 327.1 ( 1.00x)
put_hevc_pel_bi_w_pixels8_8_neon: 75.8 ( 4.32x)
put_hevc_pel_bi_w_pixels12_8_c: 728.8 ( 1.00x)
put_hevc_pel_bi_w_pixels12_8_neon: 186.1 ( 3.92x)
put_hevc_pel_bi_w_pixels16_8_c: 1288.1 ( 1.00x)
put_hevc_pel_bi_w_pixels16_8_neon: 268.5 ( 4.80x)
put_hevc_pel_bi_w_pixels24_8_c: 2855.5 ( 1.00x)
put_hevc_pel_bi_w_pixels24_8_neon: 723.8 ( 3.95x)
put_hevc_pel_bi_w_pixels32_8_c: 5095.3 ( 1.00x)
put_hevc_pel_bi_w_pixels32_8_neon: 1165.0 ( 4.37x)
put_hevc_pel_bi_w_pixels48_8_c: 11521.5 ( 1.00x)
put_hevc_pel_bi_w_pixels48_8_neon: 2856.0 ( 4.03x)
put_hevc_pel_bi_w_pixels64_8_c: 21020.5 ( 1.00x)
put_hevc_pel_bi_w_pixels64_8_neon: 4699.1 ( 4.47x)
---
libavcodec/aarch64/h26x/dsp.h | 5 +
libavcodec/aarch64/h26x/epel_neon.S | 373 ++++++++++++++++++++++
libavcodec/aarch64/hevcdsp_init_aarch64.c | 13 +
3 files changed, 391 insertions(+)
diff --git a/libavcodec/aarch64/h26x/dsp.h b/libavcodec/aarch64/h26x/dsp.h
index 6ea6a8d36a..6c91004301 100644
--- a/libavcodec/aarch64/h26x/dsp.h
+++ b/libavcodec/aarch64/h26x/dsp.h
@@ -92,6 +92,11 @@ NEON8_FNPROTO(pel_bi_pixels, (uint8_t *dst, ptrdiff_t dststride,
const uint8_t *_src, ptrdiff_t _srcstride, const int16_t *src2,
int height, intptr_t mx, intptr_t my, int width),);
+NEON8_FNPROTO(pel_bi_w_pixels, (uint8_t *_dst, ptrdiff_t _dststride,
+ const uint8_t *_src, ptrdiff_t _srcstride, const int16_t *src2,
+ int height, int denom, int wx0, int wx1,
+ int ox0, int ox1, intptr_t mx, intptr_t my, int width),);
+
NEON8_FNPROTO(epel_bi_h, (uint8_t *dst, ptrdiff_t dststride,
const uint8_t *src, ptrdiff_t srcstride, const int16_t *src2,
int height, intptr_t mx, intptr_t my, int width),);
diff --git a/libavcodec/aarch64/h26x/epel_neon.S b/libavcodec/aarch64/h26x/epel_neon.S
index e44a448b1f..4cf6339171 100644
--- a/libavcodec/aarch64/h26x/epel_neon.S
+++ b/libavcodec/aarch64/h26x/epel_neon.S
@@ -473,6 +473,379 @@ function ff_hevc_put_hevc_pel_bi_pixels64_8_neon, export=1
ret
endfunc
+.macro load_bi_w_pixels_param
+ ldrsw x8, [sp] // wx1
+#if defined(__APPLE__)
+ ldpsw x9, x10, [sp, #4] // ox0, ox1
+ ldrsw x11, [sp, #32] // width
+#else
+ ldrsw x9, [sp, #8] // ox0
+ ldrsw x10, [sp, #16] // ox1
+ ldrsw x11, [sp, 40] // width
+#endif
+.endm
+
+function ff_hevc_put_hevc_pel_bi_w_pixels4_8_neon, export=1
+ load_bi_w_pixels_param
+ add w6, w6, #6 // log2Wd
+ dup v0.8h, w7 // wx0
+ dup v1.8h, w8 // wx1
+ add w9, w9, w10
+ add w9, w9, #1 // ox0 + ox1 + 1
+ lsl w9, w9, w6
+ add w7, w6, #1 // (log2Wd + 1)
+ mov x8, #(2 * HEVC_MAX_PB_SIZE)
+ neg w7, w7
+ dup v2.4s, w9 // (ox0 + ox1 + 1) << logwWd
+ dup v6.4s, w7 // -(log2Wd + 1)
+1:
+ ld1 {v4.8b}, [x2], x3 // load src
+ ld1 {v5.8b}, [x4], x8 // load src2
+ subs w5, w5, #1
+ mov v3.16b, v2.16b
+ ushll v4.8h, v4.8b, #6
+ smlal v3.4s, v4.4h, v1.4h
+ smlal v3.4s, v5.4h, v0.4h
+ sshl v3.4s, v3.4s, v6.4s
+ sqxtn v3.4h, v3.4s
+ sqxtun v3.8b, v3.8h
+ st1 {v3.s}[0], [x0], x1
+ b.ne 1b
+ ret
+endfunc
+
+function ff_hevc_put_hevc_pel_bi_w_pixels6_8_neon, export=1
+ load_bi_w_pixels_param
+ add w6, w6, #6 // log2Wd
+ dup v0.8h, w7 // wx0
+ dup v1.8h, w8 // wx1
+ add w9, w9, w10
+ add w9, w9, #1 // ox0 + ox1 + 1
+ lsl w9, w9, w6
+ add w7, w6, #1 // (log2Wd + 1)
+ mov x8, #(2 * HEVC_MAX_PB_SIZE)
+ neg w7, w7
+ dup v2.4s, w9 // (ox0 + ox1 + 1) << logwWd
+ dup v6.4s, w7 // -(log2Wd + 1)
+ sub x1, x1, #4
+1:
+ ld1 {v4.8b}, [x2], x3 // load src
+ ld1 {v5.8h}, [x4], x8 // load src2
+ subs w5, w5, #1
+ mov v3.16b, v2.16b
+ mov v7.16b, v2.16b
+ ushll v4.8h, v4.8b, #6
+ smlal v3.4s, v4.4h, v1.4h
+ smlal v3.4s, v5.4h, v0.4h
+ smlal2 v7.4s, v4.8h, v1.8h
+ smlal2 v7.4s, v5.8h, v0.8h
+ sshl v3.4s, v3.4s, v6.4s
+ sshl v7.4s, v7.4s, v6.4s
+ sqxtn v3.4h, v3.4s
+ sqxtn2 v3.8h, v7.4s
+ sqxtun v3.8b, v3.8h
+ str s3, [x0], #4
+ st1 {v3.h}[2], [x0], x1
+ b.ne 1b
+ ret
+endfunc
+
+function ff_hevc_put_hevc_pel_bi_w_pixels8_8_neon, export=1
+ load_bi_w_pixels_param
+ add w6, w6, #6 // log2Wd
+ dup v0.8h, w7 // wx0
+ dup v1.8h, w8 // wx1
+ add w9, w9, w10
+ add w9, w9, #1 // ox0 + ox1 + 1
+ lsl w9, w9, w6
+ add w7, w6, #1 // (log2Wd + 1)
+ mov x8, #(2 * HEVC_MAX_PB_SIZE)
+ neg w7, w7
+ dup v2.4s, w9 // (ox0 + ox1 + 1) << logwWd
+ dup v6.4s, w7 // -(log2Wd + 1)
+1:
+ ld1 {v4.8b}, [x2], x3 // load src
+ ld1 {v5.8h}, [x4], x8 // load src2
+ subs w5, w5, #1
+ mov v3.16b, v2.16b
+ mov v7.16b, v2.16b
+ ushll v4.8h, v4.8b, #6
+ smlal v3.4s, v4.4h, v1.4h
+ smlal v3.4s, v5.4h, v0.4h
+ smlal2 v7.4s, v4.8h, v1.8h
+ smlal2 v7.4s, v5.8h, v0.8h
+ sshl v3.4s, v3.4s, v6.4s
+ sshl v7.4s, v7.4s, v6.4s
+ sqxtn v3.4h, v3.4s
+ sqxtn2 v3.8h, v7.4s
+ sqxtun v3.8b, v3.8h
+ st1 {v3.8b}, [x0], x1
+ b.ne 1b
+ ret
+endfunc
+
+function ff_hevc_put_hevc_pel_bi_w_pixels12_8_neon, export=1
+ load_bi_w_pixels_param
+ add w6, w6, #6 // log2Wd
+ dup v0.8h, w7 // wx0
+ dup v1.8h, w8 // wx1
+ add w9, w9, w10
+ add w9, w9, #1 // ox0 + ox1 + 1
+ lsl w9, w9, w6
+ add w7, w6, #1 // (log2Wd + 1)
+ mov x8, #(2 * HEVC_MAX_PB_SIZE)
+ neg w7, w7
+ dup v2.4s, w9 // (ox0 + ox1 + 1) << logwWd
+ dup v6.4s, w7 // -(log2Wd + 1)
+ sub x1, x1, #8
+1:
+ ld1 {v24.16b}, [x2], x3 // load src
+ ld1 {v20.16b, v21.16b}, [x4], x8 // load src2
+ subs w5, w5, #1
+
+ mov v16.16b, v2.16b
+ mov v17.16b, v2.16b
+ mov v18.16b, v2.16b
+
+ ushll v4.8h, v24.8b, #6
+ ushll2 v24.8h, v24.16b, #6
+
+ smlal v16.4s, v4.4h, v1.4h
+ smlal v16.4s, v20.4h, v0.4h
+ smlal2 v17.4s, v4.8h, v1.8h
+ smlal2 v17.4s, v20.8h, v0.8h
+ smlal v18.4s, v24.4h, v1.4h
+ smlal v18.4s, v21.4h, v0.4h
+
+ sshl v16.4s, v16.4s, v6.4s
+ sshl v17.4s, v17.4s, v6.4s
+ sshl v18.4s, v18.4s, v6.4s
+
+ sqxtn v16.4h, v16.4s
+ sqxtn2 v16.8h, v17.4s
+ sqxtn v18.4h, v18.4s
+ sqxtun v3.8b, v16.8h
+ sqxtun2 v3.16b, v18.8h
+ str d3, [x0], #8
+ st1 {v3.s}[2], [x0], x1
+ b.ne 1b
+ ret
+endfunc
+
+function ff_hevc_put_hevc_pel_bi_w_pixels16_8_neon, export=1
+ load_bi_w_pixels_param
+ add w6, w6, #6 // log2Wd
+ dup v0.8h, w7 // wx0
+ dup v1.8h, w8 // wx1
+ add w9, w9, w10
+ add w9, w9, #1 // ox0 + ox1 + 1
+ lsl w9, w9, w6
+ add w7, w6, #1 // (log2Wd + 1)
+ mov x8, #(2 * HEVC_MAX_PB_SIZE)
+ neg w7, w7
+ dup v2.4s, w9 // (ox0 + ox1 + 1) << logwWd
+ dup v6.4s, w7 // -(log2Wd + 1)
+1:
+ ld1 {v24.16b}, [x2], x3 // load src
+ ld1 {v20.16b, v21.16b}, [x4], x8 // load src2
+ subs w5, w5, #1
+
+ mov v16.16b, v2.16b
+ mov v17.16b, v2.16b
+ mov v18.16b, v2.16b
+ mov v19.16b, v2.16b
+
+ ushll v4.8h, v24.8b, #6
+ ushll2 v24.8h, v24.16b, #6
+
+ smlal v16.4s, v4.4h, v1.4h
+ smlal v16.4s, v20.4h, v0.4h
+ smlal2 v17.4s, v4.8h, v1.8h
+ smlal2 v17.4s, v20.8h, v0.8h
+ smlal v18.4s, v24.4h, v1.4h
+ smlal v18.4s, v21.4h, v0.4h
+ smlal2 v19.4s, v24.8h, v1.8h
+ smlal2 v19.4s, v21.8h, v0.8h
+
+ sshl v16.4s, v16.4s, v6.4s
+ sshl v17.4s, v17.4s, v6.4s
+ sshl v18.4s, v18.4s, v6.4s
+ sshl v19.4s, v19.4s, v6.4s
+
+ sqxtn v16.4h, v16.4s
+ sqxtn2 v16.8h, v17.4s
+ sqxtn v18.4h, v18.4s
+ sqxtn2 v18.8h, v19.4s
+ sqxtun v3.8b, v16.8h
+ sqxtun2 v3.16b, v18.8h
+ st1 {v3.16b}, [x0], x1
+ b.ne 1b
+ ret
+endfunc
+
+function ff_hevc_put_hevc_pel_bi_w_pixels24_8_neon, export=1
+ load_bi_w_pixels_param
+ add w6, w6, #6 // log2Wd
+ dup v0.8h, w7 // wx0
+ dup v1.8h, w8 // wx1
+ add w9, w9, w10
+ add w9, w9, #1 // ox0 + ox1 + 1
+ lsl w9, w9, w6
+ add w7, w6, #1 // (log2Wd + 1)
+ mov x8, #(2 * HEVC_MAX_PB_SIZE)
+ neg w7, w7
+ dup v2.4s, w9 // (ox0 + ox1 + 1) << logwWd
+ dup v6.4s, w7 // -(log2Wd + 1)
+ mov x7, #24
+ sub x3, x3, x11
+ sub x8, x8, x11, lsl #1
+ sub x1, x1, x11
+1:
+ mov w6, w11
+2:
+ ld1 {v24.16b, v25.16b}, [x2], x7
+ ld1 {v20.8h, v21.8h, v22.8h}, [x4], #48
+
+ subs w6, w6, #24
+
+ mov v16.16b, v2.16b
+ mov v17.16b, v2.16b
+ mov v18.16b, v2.16b
+ mov v19.16b, v2.16b
+ mov v26.16b, v2.16b
+ mov v27.16b, v2.16b
+
+ ushll v4.8h, v24.8b, #6
+ ushll2 v24.8h, v24.16b, #6
+ ushll v5.8h, v25.8b, #6
+
+ smlal v16.4s, v4.4h, v1.4h
+ smlal v16.4s, v20.4h, v0.4h
+ smlal2 v17.4s, v4.8h, v1.8h
+ smlal2 v17.4s, v20.8h, v0.8h
+ smlal v18.4s, v24.4h, v1.4h
+ smlal v18.4s, v21.4h, v0.4h
+ smlal2 v19.4s, v24.8h, v1.8h
+ smlal2 v19.4s, v21.8h, v0.8h
+ smlal v26.4s, v5.4h, v1.4h
+ smlal v26.4s, v22.4h, v0.4h
+ smlal2 v27.4s, v5.8h, v1.8h
+ smlal2 v27.4s, v22.8h, v0.8h
+
+ sshl v16.4s, v16.4s, v6.4s
+ sshl v17.4s, v17.4s, v6.4s
+ sshl v18.4s, v18.4s, v6.4s
+ sshl v19.4s, v19.4s, v6.4s
+ sshl v26.4s, v26.4s, v6.4s
+ sshl v27.4s, v27.4s, v6.4s
+
+ sqxtn v16.4h, v16.4s
+ sqxtn2 v16.8h, v17.4s
+ sqxtn v18.4h, v18.4s
+ sqxtn2 v18.8h, v19.4s
+ sqxtn v26.4h, v26.4s
+ sqxtn2 v26.8h, v27.4s
+ sqxtun v3.8b, v16.8h
+ sqxtun2 v3.16b, v18.8h
+ sqxtun v4.8b, v26.8h
+ str q3, [x0], #16
+ str d4, [x0], #8
+ b.ne 2b
+
+ subs w5, w5, #1
+ add x0, x0, x1
+ add x2, x2, x3
+ add x4, x4, x8
+ b.ne 1b
+ ret
+endfunc
+
+function ff_hevc_put_hevc_pel_bi_w_pixels32_8_neon, export=1
+ load_bi_w_pixels_param
+ add w6, w6, #6 // log2Wd
+ dup v0.8h, w7 // wx0
+ dup v1.8h, w8 // wx1
+ add w9, w9, w10
+ add w9, w9, #1 // ox0 + ox1 + 1
+ lsl w9, w9, w6
+ add w7, w6, #1 // (log2Wd + 1)
+ mov x8, #(2 * HEVC_MAX_PB_SIZE)
+ neg w7, w7
+ dup v2.4s, w9 // (ox0 + ox1 + 1) << logwWd
+ dup v6.4s, w7 // -(log2Wd + 1)
+ sub x3, x3, x11
+ sub x8, x8, x11, lsl #1
+ sub x1, x1, x11
+1:
+ mov w6, w11
+2:
+ ld1 {v24.16b, v25.16b}, [x2], #32 // load src
+ ld1 {v20.8h, v21.8h, v22.8h, v23.8h}, [x4], #64 // load src2
+
+ subs w6, w6, #32
+
+ mov v16.16b, v2.16b
+ mov v17.16b, v2.16b
+ mov v18.16b, v2.16b
+ mov v19.16b, v2.16b
+ mov v26.16b, v2.16b
+ mov v27.16b, v2.16b
+ mov v28.16b, v2.16b
+ mov v29.16b, v2.16b
+
+ ushll v4.8h, v24.8b, #6
+ ushll2 v24.8h, v24.16b, #6
+ ushll v5.8h, v25.8b, #6
+ ushll2 v25.8h, v25.16b, #6
+
+ smlal v16.4s, v4.4h, v1.4h
+ smlal v16.4s, v20.4h, v0.4h
+ smlal2 v17.4s, v4.8h, v1.8h
+ smlal2 v17.4s, v20.8h, v0.8h
+ smlal v18.4s, v24.4h, v1.4h
+ smlal v18.4s, v21.4h, v0.4h
+ smlal2 v19.4s, v24.8h, v1.8h
+ smlal2 v19.4s, v21.8h, v0.8h
+ smlal v26.4s, v5.4h, v1.4h
+ smlal v26.4s, v22.4h, v0.4h
+ smlal2 v27.4s, v5.8h, v1.8h
+ smlal2 v27.4s, v22.8h, v0.8h
+ smlal v28.4s, v25.4h, v1.4h
+ smlal v28.4s, v23.4h, v0.4h
+ smlal2 v29.4s, v25.8h, v1.8h
+ smlal2 v29.4s, v23.8h, v0.8h
+
+ sshl v16.4s, v16.4s, v6.4s
+ sshl v17.4s, v17.4s, v6.4s
+ sshl v18.4s, v18.4s, v6.4s
+ sshl v19.4s, v19.4s, v6.4s
+ sshl v26.4s, v26.4s, v6.4s
+ sshl v27.4s, v27.4s, v6.4s
+ sshl v28.4s, v28.4s, v6.4s
+ sshl v29.4s, v29.4s, v6.4s
+
+ sqxtn v16.4h, v16.4s
+ sqxtn2 v16.8h, v17.4s
+ sqxtn v18.4h, v18.4s
+ sqxtn2 v18.8h, v19.4s
+ sqxtn v26.4h, v26.4s
+ sqxtn2 v26.8h, v27.4s
+ sqxtn v28.4h, v28.4s
+ sqxtn2 v28.8h, v29.4s
+ sqxtun v3.8b, v16.8h
+ sqxtun2 v3.16b, v18.8h
+ sqxtun v4.8b, v26.8h
+ sqxtun2 v4.16b, v28.8h
+ st1 {v3.16b, v4.16b}, [x0], #32
+ b.ne 2b
+
+ subs w5, w5, #1
+ add x0, x0, x1
+ add x2, x2, x3
+ add x4, x4, x8
+ b.ne 1b
+ ret
+endfunc
function ff_hevc_put_hevc_epel_bi_h4_8_neon, export=1
load_epel_filterb x6, x7
diff --git a/libavcodec/aarch64/hevcdsp_init_aarch64.c b/libavcodec/aarch64/hevcdsp_init_aarch64.c
index 0b159d1886..1d37cd76d8 100644
--- a/libavcodec/aarch64/hevcdsp_init_aarch64.c
+++ b/libavcodec/aarch64/hevcdsp_init_aarch64.c
@@ -134,6 +134,17 @@ void ff_hevc_transform_luma_4x4_neon_8(int16_t *coeffs);
member[7][v][h] = ff_hevc_put_hevc_##fn##32_8_neon##ext; \
member[9][v][h] = ff_hevc_put_hevc_##fn##64_8_neon##ext;
+#define NEON8_FNASSIGN_PARTIAL_6(member, v, h, fn, ext) \
+ member[1][v][h] = ff_hevc_put_hevc_##fn##4_8_neon##ext; \
+ member[2][v][h] = ff_hevc_put_hevc_##fn##6_8_neon##ext; \
+ member[3][v][h] = ff_hevc_put_hevc_##fn##8_8_neon##ext; \
+ member[4][v][h] = ff_hevc_put_hevc_##fn##12_8_neon##ext; \
+ member[5][v][h] = ff_hevc_put_hevc_##fn##16_8_neon##ext; \
+ member[6][v][h] = ff_hevc_put_hevc_##fn##24_8_neon##ext; \
+ member[7][v][h] = ff_hevc_put_hevc_##fn##32_8_neon##ext; \
+ member[8][v][h] = ff_hevc_put_hevc_##fn##24_8_neon##ext; \
+ member[9][v][h] = ff_hevc_put_hevc_##fn##32_8_neon##ext;
+
av_cold void ff_hevc_dsp_init_aarch64(HEVCDSPContext *c, const int bit_depth)
{
int cpu_flags = av_get_cpu_flags();
@@ -204,6 +215,8 @@ av_cold void ff_hevc_dsp_init_aarch64(HEVCDSPContext *c, const int bit_depth)
NEON8_FNASSIGN(c->put_hevc_epel_bi, 1, 0, epel_bi_v,);
NEON8_FNASSIGN(c->put_hevc_qpel_bi, 0, 0, pel_bi_pixels,);
NEON8_FNASSIGN(c->put_hevc_qpel_bi, 1, 0, qpel_bi_v,);
+ NEON8_FNASSIGN_PARTIAL_6(c->put_hevc_qpel_bi_w, 0, 0, pel_bi_w_pixels,);
+ NEON8_FNASSIGN_PARTIAL_6(c->put_hevc_epel_bi_w, 0, 0, pel_bi_w_pixels,);
NEON8_FNASSIGN(c->put_hevc_epel_uni, 0, 0, pel_uni_pixels,);
NEON8_FNASSIGN(c->put_hevc_epel_uni, 1, 0, epel_uni_v,);
NEON8_FNASSIGN(c->put_hevc_qpel_uni, 0, 0, pel_uni_pixels,);
--
2.46.0
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".