* [FFmpeg-devel] [PATCH 2/4] lavc/vp8dsp: R-V V loop_filter_simple
[not found] <20240622155806.3191984-1-uk7b@foxmail.com>
@ 2024-06-22 15:58 ` uk7b
2024-06-24 20:19 ` Rémi Denis-Courmont
2024-06-22 15:58 ` [FFmpeg-devel] [PATCH 3/4] lavc/vp8dsp: R-V V loop_filter_inner uk7b
2024-06-22 15:58 ` [FFmpeg-devel] [PATCH 4/4] lavc/vp8dsp: R-V V loop_filter uk7b
2 siblings, 1 reply; 4+ messages in thread
From: uk7b @ 2024-06-22 15:58 UTC (permalink / raw)
To: ffmpeg-devel; +Cc: sunyuechi
From: sunyuechi <sunyuechi@iscas.ac.cn>
C908 X60
vp8_loop_filter_simple_h_c : 7.0 6.0
vp8_loop_filter_simple_h_rvv_i32 : 3.2 2.7
vp8_loop_filter_simple_v_c : 7.2 6.5
vp8_loop_filter_simple_v_rvv_i32 : 1.7 1.2
---
libavcodec/riscv/vp8dsp_init.c | 18 ++++++-
libavcodec/riscv/vp8dsp_rvv.S | 87 ++++++++++++++++++++++++++++++++++
2 files changed, 104 insertions(+), 1 deletion(-)
diff --git a/libavcodec/riscv/vp8dsp_init.c b/libavcodec/riscv/vp8dsp_init.c
index dcb6307d5b..8c5b2c8b04 100644
--- a/libavcodec/riscv/vp8dsp_init.c
+++ b/libavcodec/riscv/vp8dsp_init.c
@@ -49,6 +49,9 @@ VP8_BILIN(16, rvv256);
VP8_BILIN(8, rvv256);
VP8_BILIN(4, rvv256);
+VP8_LF(rvv128);
+VP8_LF(rvv256);
+
av_cold void ff_vp78dsp_init_riscv(VP8DSPContext *c)
{
#if HAVE_RV
@@ -147,9 +150,15 @@ av_cold void ff_vp78dsp_init_riscv(VP8DSPContext *c)
av_cold void ff_vp8dsp_init_riscv(VP8DSPContext *c)
{
#if HAVE_RVV
+ int vlenb = ff_get_rv_vlenb();
+
+#define init_loop_filter(vlen) \
+ c->vp8_v_loop_filter_simple = ff_vp8_v_loop_filter16_simple_rvv##vlen; \
+ c->vp8_h_loop_filter_simple = ff_vp8_h_loop_filter16_simple_rvv##vlen;
+
int flags = av_get_cpu_flags();
- if (flags & AV_CPU_FLAG_RVV_I32 && ff_rv_vlen_least(128)) {
+ if (flags & AV_CPU_FLAG_RVV_I32 && vlenb >= 16) {
#if __riscv_xlen >= 64
if (flags & AV_CPU_FLAG_RVV_I64)
c->vp8_luma_dc_wht = ff_vp8_luma_dc_wht_rvv;
@@ -159,6 +168,13 @@ av_cold void ff_vp8dsp_init_riscv(VP8DSPContext *c)
c->vp8_idct_dc_add4y = ff_vp8_idct_dc_add4y_rvv;
if (flags & AV_CPU_FLAG_RVV_I64)
c->vp8_idct_dc_add4uv = ff_vp8_idct_dc_add4uv_rvv;
+
+ if (vlenb >= 32) {
+ init_loop_filter(256);
+ } else {
+ init_loop_filter(128);
+ }
}
+#undef init_loop_filter
#endif
}
diff --git a/libavcodec/riscv/vp8dsp_rvv.S b/libavcodec/riscv/vp8dsp_rvv.S
index 0cbf1672f7..b5f8bb31b4 100644
--- a/libavcodec/riscv/vp8dsp_rvv.S
+++ b/libavcodec/riscv/vp8dsp_rvv.S
@@ -275,6 +275,93 @@ func ff_vp78_idct_dc_add4uv_rvv, zve64x
ret
endfunc
+.macro filter_fmin len, vlen, a, f1, p0f2, q0f1
+ vsetvlstatic16 \len, \vlen
+ vsext.vf2 \q0f1, \a
+ vmin.vx \p0f2, \q0f1, a7
+ vmin.vx \q0f1, \q0f1, t3
+ vadd.vi \p0f2, \p0f2, 3
+ vadd.vi \q0f1, \q0f1, 4
+ vsra.vi \p0f2, \p0f2, 3
+ vsra.vi \f1, \q0f1, 3
+ vadd.vv \p0f2, \p0f2, v8
+ vsub.vv \q0f1, v16, \f1
+ vmax.vx \p0f2, \p0f2, zero
+ vmax.vx \q0f1, \q0f1, zero
+.endm
+
+.macro filter len, vlen, type, normal, inner, dst, stride, fE, fI, thresh
+.ifc \type,v
+ slli a6, \stride, 1
+ sub t2, \dst, a6
+ add t4, \dst, \stride
+ sub t1, \dst, \stride
+ vle8.v v1, (t2)
+ vle8.v v11, (t4)
+ vle8.v v17, (t1)
+ vle8.v v22, (\dst)
+.else
+ addi t1, \dst, -1
+ addi a6, \dst, -2
+ addi t4, \dst, 1
+ vlse8.v v1, (a6), \stride
+ vlse8.v v11, (t4), \stride
+ vlse8.v v17, (t1), \stride
+ vlse8.v v22, (\dst), \stride
+.endif
+ vwsubu.vv v12, v1, v11 // p1-q1
+ vwsubu.vv v24, v22, v17 // q0-p0
+ vnclip.wi v23, v12, 0
+ vsetvlstatic16 \len, \vlen
+ // vp8_simple_limit(dst + i, stride, flim)
+ li a7, 2
+ vneg.v v18, v12
+ vmax.vv v18, v18, v12
+ vneg.v v8, v24
+ vmax.vv v8, v8, v24
+ vsrl.vi v18, v18, 1
+ vmacc.vx v18, a7, v8
+ vmsleu.vx v0, v18, \fE
+
+ li t5, 3
+ li a7, 124
+ li t3, 123
+ vmul.vx v30, v24, t5
+ vsext.vf2 v4, v23
+ vzext.vf2 v8, v17 // p0
+ vzext.vf2 v16, v22 // q0
+ vadd.vv v12, v30, v4
+ vsetvlstatic8 \len, \vlen
+ vnclip.wi v11, v12, 0
+ filter_fmin \len, \vlen, v11, v24, v4, v6
+ vsetvlstatic8 \len, \vlen
+ vnclipu.wi v4, v4, 0
+ vnclipu.wi v6, v6, 0
+
+.ifc \type,v
+ vse8.v v4, (t1), v0.t
+ vse8.v v6, (\dst), v0.t
+.else
+ vsse8.v v4, (t1), \stride, v0.t
+ vsse8.v v6, (\dst), \stride, v0.t
+.endif
+
+.endm
+
+.irp vlen,256,128
+func ff_vp8_v_loop_filter16_simple_rvv\vlen, zve32x
+ vsetvlstatic8 16, \vlen
+ filter 16, \vlen, v, 0, 0, a0, a1, a2, a3, a4
+ ret
+endfunc
+
+func ff_vp8_h_loop_filter16_simple_rvv\vlen, zve32x
+ vsetvlstatic8 16, \vlen
+ filter 16, \vlen, h, 0, 0, a0, a1, a2, a3, a4
+ ret
+endfunc
+.endr
+
.macro bilin_load_h dst mn
addi t5, a2, 1
vle8.v \dst, (a2)
--
2.45.2
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
^ permalink raw reply [flat|nested] 4+ messages in thread
* [FFmpeg-devel] [PATCH 3/4] lavc/vp8dsp: R-V V loop_filter_inner
[not found] <20240622155806.3191984-1-uk7b@foxmail.com>
2024-06-22 15:58 ` [FFmpeg-devel] [PATCH 2/4] lavc/vp8dsp: R-V V loop_filter_simple uk7b
@ 2024-06-22 15:58 ` uk7b
2024-06-22 15:58 ` [FFmpeg-devel] [PATCH 4/4] lavc/vp8dsp: R-V V loop_filter uk7b
2 siblings, 0 replies; 4+ messages in thread
From: uk7b @ 2024-06-22 15:58 UTC (permalink / raw)
To: ffmpeg-devel; +Cc: sunyuechi
From: sunyuechi <sunyuechi@iscas.ac.cn>
C908 X60
vp8_loop_filter8uv_inner_v_c : 12.5 11.0
vp8_loop_filter8uv_inner_v_rvv_i32 : 7.7 6.2
vp8_loop_filter16y_inner_h_c : 11.7 10.2
vp8_loop_filter16y_inner_h_rvv_i32 : 8.5 6.5
vp8_loop_filter16y_inner_v_c : 11.5 10.7
vp8_loop_filter16y_inner_v_rvv_i32 : 5.0 3.5
---
libavcodec/riscv/vp8dsp_init.c | 5 +-
libavcodec/riscv/vp8dsp_rvv.S | 104 +++++++++++++++++++++++++++++++++
2 files changed, 108 insertions(+), 1 deletion(-)
diff --git a/libavcodec/riscv/vp8dsp_init.c b/libavcodec/riscv/vp8dsp_init.c
index 8c5b2c8b04..94f78cd84b 100644
--- a/libavcodec/riscv/vp8dsp_init.c
+++ b/libavcodec/riscv/vp8dsp_init.c
@@ -154,7 +154,10 @@ av_cold void ff_vp8dsp_init_riscv(VP8DSPContext *c)
#define init_loop_filter(vlen) \
c->vp8_v_loop_filter_simple = ff_vp8_v_loop_filter16_simple_rvv##vlen; \
- c->vp8_h_loop_filter_simple = ff_vp8_h_loop_filter16_simple_rvv##vlen;
+ c->vp8_h_loop_filter_simple = ff_vp8_h_loop_filter16_simple_rvv##vlen; \
+ c->vp8_v_loop_filter16y_inner = ff_vp8_v_loop_filter16_inner_rvv##vlen; \
+ c->vp8_h_loop_filter16y_inner = ff_vp8_h_loop_filter16_inner_rvv##vlen; \
+ c->vp8_v_loop_filter8uv_inner = ff_vp8_v_loop_filter8uv_inner_rvv##vlen;
int flags = av_get_cpu_flags();
diff --git a/libavcodec/riscv/vp8dsp_rvv.S b/libavcodec/riscv/vp8dsp_rvv.S
index b5f8bb31b4..ed789ec4fd 100644
--- a/libavcodec/riscv/vp8dsp_rvv.S
+++ b/libavcodec/riscv/vp8dsp_rvv.S
@@ -275,6 +275,13 @@ func ff_vp78_idct_dc_add4uv_rvv, zve64x
ret
endfunc
+.macro filter_abs dst, diff, fI
+ vneg.v v8, \diff
+ vmax.vv \dst, v8, \diff
+ vmsleu.vx v8, \dst, \fI
+ vmand.mm v27, v27, v8
+.endm
+
.macro filter_fmin len, vlen, a, f1, p0f2, q0f1
vsetvlstatic16 \len, \vlen
vsext.vf2 \q0f1, \a
@@ -300,6 +307,16 @@ endfunc
vle8.v v11, (t4)
vle8.v v17, (t1)
vle8.v v22, (\dst)
+ .if \normal
+ sub t3, t2, a6
+ sub t0, t1, a6
+ add t6, \dst, a6
+ add a7, t4, a6
+ vle8.v v2, (t3)
+ vle8.v v15, (t0)
+ vle8.v v10, (t6)
+ vle8.v v14, (a7)
+ .endif
.else
addi t1, \dst, -1
addi a6, \dst, -2
@@ -308,9 +325,27 @@ endfunc
vlse8.v v11, (t4), \stride
vlse8.v v17, (t1), \stride
vlse8.v v22, (\dst), \stride
+ .if \normal
+ addi t5, \dst, -4
+ addi t0, \dst, -3
+ addi t6, \dst, 2
+ addi a7, \dst, 3
+ vlse8.v v2, (t5), \stride
+ vlse8.v v15, (t0), \stride
+ vlse8.v v10, (t6), \stride
+ vlse8.v v14, (a7), \stride
+ .endif
.endif
vwsubu.vv v12, v1, v11 // p1-q1
vwsubu.vv v24, v22, v17 // q0-p0
+.if \normal
+ vwsubu.vv v30, v1, v17
+ vwsubu.vv v20, v11, v22
+ vwsubu.vv v28, v1, v15
+ vwsubu.vv v4, v2, v15
+ vwsubu.vv v6, v10, v11
+ vwsubu.vv v2, v14, v10
+.endif
vnclip.wi v23, v12, 0
vsetvlstatic16 \len, \vlen
// vp8_simple_limit(dst + i, stride, flim)
@@ -322,6 +357,25 @@ endfunc
vsrl.vi v18, v18, 1
vmacc.vx v18, a7, v8
vmsleu.vx v0, v18, \fE
+.if \normal
+ vneg.v v18, v30
+ vmax.vv v30, v18, v30
+ vmsleu.vx v27, v30, \fI
+ filter_abs v18, v28, \fI
+ filter_abs v18, v4, \fI
+ filter_abs v18, v6, \fI
+ filter_abs v18, v2, \fI
+ filter_abs v20, v20, \fI
+ vmand.mm v27, v0, v27 // vp8_simple_limit && normal
+
+ vmsgtu.vx v20, v20, \thresh // hev
+ vmsgtu.vx v3, v30, \thresh
+ vmor.mm v3, v3, v20 // v3 = hev: > thresh
+ vzext.vf2 v18, v1 // v18 = p1
+ vmand.mm v0, v27, v3 // v0 = normal && hev
+ vzext.vf2 v20, v11 // v12 = q1
+ vmnot.m v3, v3 // v3 = !hv
+.endif
li t5, 3
li a7, 124
@@ -346,6 +400,37 @@ endfunc
vsse8.v v6, (\dst), \stride, v0.t
.endif
+.if \normal
+ vmand.mm v0, v27, v3 // vp8_normal_limit & !hv
+
+ .if \inner
+ vnclip.wi v30, v30, 0
+ filter_fmin \len, \vlen, v30, v24, v4, v6
+ vadd.vi v24, v24, 1
+ vsra.vi v24, v24, 1 // (f1 + 1) >> 1;
+ vadd.vv v8, v18, v24
+ vsub.vv v10, v20, v24
+ .endif
+
+ vmax.vx v8, v8, zero
+ vmax.vx v10, v10, zero
+ vsetvlstatic8 \len, \vlen
+ vnclipu.wi v4, v4, 0
+ vnclipu.wi v5, v6, 0
+ vnclipu.wi v6, v8, 0
+ vnclipu.wi v7, v10, 0
+ .ifc \type,v
+ vse8.v v4, (t1), v0.t
+ vse8.v v5, (\dst), v0.t
+ vse8.v v6, (t2), v0.t
+ vse8.v v7, (t4), v0.t
+ .else
+ vsse8.v v4, (t1), \stride, v0.t
+ vsse8.v v5, (\dst), \stride, v0.t
+ vsse8.v v6, (a6), \stride, v0.t
+ vsse8.v v7, (t4), \stride, v0.t
+ .endif
+.endif
.endm
.irp vlen,256,128
@@ -360,6 +445,25 @@ func ff_vp8_h_loop_filter16_simple_rvv\vlen, zve32x
filter 16, \vlen, h, 0, 0, a0, a1, a2, a3, a4
ret
endfunc
+
+func ff_vp8_h_loop_filter16_inner_rvv\vlen, zve32x
+ vsetvlstatic8 16, \vlen
+ filter 16, \vlen, h, 1, 1, a0, a1, a2, a3, a4
+ ret
+endfunc
+
+func ff_vp8_v_loop_filter16_inner_rvv\vlen, zve32x
+ vsetvlstatic8 16, \vlen
+ filter 16, \vlen, v, 1, 1, a0, a1, a2, a3, a4
+ ret
+endfunc
+
+func ff_vp8_v_loop_filter8uv_inner_rvv\vlen, zve32x
+ vsetvlstatic8 8, \vlen
+ filter 8, \vlen, v, 1, 1, a0, a2, a3, a4, a5
+ filter 8, \vlen, v, 1, 1, a1, a2, a3, a4, a5
+ ret
+endfunc
.endr
.macro bilin_load_h dst mn
--
2.45.2
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
^ permalink raw reply [flat|nested] 4+ messages in thread
* [FFmpeg-devel] [PATCH 4/4] lavc/vp8dsp: R-V V loop_filter
[not found] <20240622155806.3191984-1-uk7b@foxmail.com>
2024-06-22 15:58 ` [FFmpeg-devel] [PATCH 2/4] lavc/vp8dsp: R-V V loop_filter_simple uk7b
2024-06-22 15:58 ` [FFmpeg-devel] [PATCH 3/4] lavc/vp8dsp: R-V V loop_filter_inner uk7b
@ 2024-06-22 15:58 ` uk7b
2 siblings, 0 replies; 4+ messages in thread
From: uk7b @ 2024-06-22 15:58 UTC (permalink / raw)
To: ffmpeg-devel; +Cc: sunyuechi
From: sunyuechi <sunyuechi@iscas.ac.cn>
C908 X60
vp8_loop_filter8uv_v_c : 13.7 11.7
vp8_loop_filter8uv_v_rvv_i32 : 7.7 6.2
vp8_loop_filter16y_h_c : 12.2 11.2
vp8_loop_filter16y_h_rvv_i32 : 9.5 7.2
vp8_loop_filter16y_v_c : 13.2 12.0
vp8_loop_filter16y_v_rvv_i32 : 5.5 3.7
---
libavcodec/riscv/vp8dsp_init.c | 5 ++-
libavcodec/riscv/vp8dsp_rvv.S | 57 ++++++++++++++++++++++++++++++++++
2 files changed, 61 insertions(+), 1 deletion(-)
diff --git a/libavcodec/riscv/vp8dsp_init.c b/libavcodec/riscv/vp8dsp_init.c
index 94f78cd84b..72191f558b 100644
--- a/libavcodec/riscv/vp8dsp_init.c
+++ b/libavcodec/riscv/vp8dsp_init.c
@@ -157,7 +157,10 @@ av_cold void ff_vp8dsp_init_riscv(VP8DSPContext *c)
c->vp8_h_loop_filter_simple = ff_vp8_h_loop_filter16_simple_rvv##vlen; \
c->vp8_v_loop_filter16y_inner = ff_vp8_v_loop_filter16_inner_rvv##vlen; \
c->vp8_h_loop_filter16y_inner = ff_vp8_h_loop_filter16_inner_rvv##vlen; \
- c->vp8_v_loop_filter8uv_inner = ff_vp8_v_loop_filter8uv_inner_rvv##vlen;
+ c->vp8_v_loop_filter8uv_inner = ff_vp8_v_loop_filter8uv_inner_rvv##vlen; \
+ c->vp8_v_loop_filter16y = ff_vp8_v_loop_filter16_rvv##vlen; \
+ c->vp8_h_loop_filter16y = ff_vp8_h_loop_filter16_rvv##vlen; \
+ c->vp8_v_loop_filter8uv = ff_vp8_v_loop_filter8uv_rvv##vlen;
int flags = av_get_cpu_flags();
diff --git a/libavcodec/riscv/vp8dsp_rvv.S b/libavcodec/riscv/vp8dsp_rvv.S
index ed789ec4fd..98ff389b9a 100644
--- a/libavcodec/riscv/vp8dsp_rvv.S
+++ b/libavcodec/riscv/vp8dsp_rvv.S
@@ -410,6 +410,33 @@ endfunc
vsra.vi v24, v24, 1 // (f1 + 1) >> 1;
vadd.vv v8, v18, v24
vsub.vv v10, v20, v24
+ .else
+ li t5, 27
+ li t3, 9
+ li a7, 18
+ vwmul.vx v2, v11, t5
+ vwmul.vx v6, v11, t3
+ vwmul.vx v4, v11, a7
+ vsetvlstatic16 \len, \vlen
+ li a7, 63
+ vzext.vf2 v14, v15 // p2
+ vzext.vf2 v24, v10 // q2
+ vadd.vx v2, v2, a7
+ vadd.vx v4, v4, a7
+ vadd.vx v6, v6, a7
+ vsra.vi v2, v2, 7 // a0
+ vsra.vi v12, v4, 7 // a1
+ vsra.vi v6, v6, 7 // a2
+ vadd.vv v14, v14, v6 // p2 + a2
+ vsub.vv v22, v24, v6 // q2 - a2
+ vsub.vv v10, v20, v12 // q1 - a1
+ vadd.vv v4, v8, v2 // p0 + a0
+ vsub.vv v6, v16, v2 // q0 - a0
+ vadd.vv v8, v12, v18 // a1 + p1
+ vmax.vx v4, v4, zero
+ vmax.vx v6, v6, zero
+ vmax.vx v14, v14, zero
+ vmax.vx v16, v22, zero
.endif
vmax.vx v8, v8, zero
@@ -430,6 +457,17 @@ endfunc
vsse8.v v6, (a6), \stride, v0.t
vsse8.v v7, (t4), \stride, v0.t
.endif
+ .if !\inner
+ vnclipu.wi v14, v14, 0
+ vnclipu.wi v16, v16, 0
+ .ifc \type,v
+ vse8.v v14, (t0), v0.t
+ vse8.v v16, (t6), v0.t
+ .else
+ vsse8.v v14, (t0), \stride, v0.t
+ vsse8.v v16, (t6), \stride, v0.t
+ .endif
+ .endif
.endif
.endm
@@ -464,6 +502,25 @@ func ff_vp8_v_loop_filter8uv_inner_rvv\vlen, zve32x
filter 8, \vlen, v, 1, 1, a1, a2, a3, a4, a5
ret
endfunc
+
+func ff_vp8_v_loop_filter16_rvv\vlen, zve32x
+ vsetvlstatic8 16, \vlen
+ filter 16, \vlen, v, 1, 0, a0, a1, a2, a3, a4
+ ret
+endfunc
+
+func ff_vp8_h_loop_filter16_rvv\vlen, zve32x
+ vsetvlstatic8 16, \vlen
+ filter 16, \vlen, h, 1, 0, a0, a1, a2, a3, a4
+ ret
+endfunc
+
+func ff_vp8_v_loop_filter8uv_rvv\vlen, zve32x
+ vsetvlstatic8 8, \vlen
+ filter 8, \vlen, v, 1, 0, a0, a2, a3, a4, a5
+ filter 8, \vlen, v, 1, 0, a1, a2, a3, a4, a5
+ ret
+endfunc
.endr
.macro bilin_load_h dst mn
--
2.45.2
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
^ permalink raw reply [flat|nested] 4+ messages in thread
* Re: [FFmpeg-devel] [PATCH 2/4] lavc/vp8dsp: R-V V loop_filter_simple
2024-06-22 15:58 ` [FFmpeg-devel] [PATCH 2/4] lavc/vp8dsp: R-V V loop_filter_simple uk7b
@ 2024-06-24 20:19 ` Rémi Denis-Courmont
0 siblings, 0 replies; 4+ messages in thread
From: Rémi Denis-Courmont @ 2024-06-24 20:19 UTC (permalink / raw)
To: ffmpeg-devel
Le lauantaina 22. kesäkuuta 2024, 18.58.04 EEST uk7b@foxmail.com a écrit :
> From: sunyuechi <sunyuechi@iscas.ac.cn>
>
> C908 X60
> vp8_loop_filter_simple_h_c : 7.0 6.0
> vp8_loop_filter_simple_h_rvv_i32 : 3.2 2.7
> vp8_loop_filter_simple_v_c : 7.2 6.5
> vp8_loop_filter_simple_v_rvv_i32 : 1.7 1.2
> ---
> libavcodec/riscv/vp8dsp_init.c | 18 ++++++-
> libavcodec/riscv/vp8dsp_rvv.S | 87 ++++++++++++++++++++++++++++++++++
> 2 files changed, 104 insertions(+), 1 deletion(-)
>
> diff --git a/libavcodec/riscv/vp8dsp_init.c b/libavcodec/riscv/vp8dsp_init.c
> index dcb6307d5b..8c5b2c8b04 100644
> --- a/libavcodec/riscv/vp8dsp_init.c
> +++ b/libavcodec/riscv/vp8dsp_init.c
> @@ -49,6 +49,9 @@ VP8_BILIN(16, rvv256);
> VP8_BILIN(8, rvv256);
> VP8_BILIN(4, rvv256);
>
> +VP8_LF(rvv128);
> +VP8_LF(rvv256);
> +
> av_cold void ff_vp78dsp_init_riscv(VP8DSPContext *c)
> {
> #if HAVE_RV
> @@ -147,9 +150,15 @@ av_cold void ff_vp78dsp_init_riscv(VP8DSPContext *c)
> av_cold void ff_vp8dsp_init_riscv(VP8DSPContext *c)
> {
> #if HAVE_RVV
> + int vlenb = ff_get_rv_vlenb();
> +
> +#define init_loop_filter(vlen) \
> + c->vp8_v_loop_filter_simple = ff_vp8_v_loop_filter16_simple_rvv##vlen;
> \ + c->vp8_h_loop_filter_simple =
> ff_vp8_h_loop_filter16_simple_rvv##vlen; +
> int flags = av_get_cpu_flags();
>
> - if (flags & AV_CPU_FLAG_RVV_I32 && ff_rv_vlen_least(128)) {
> + if (flags & AV_CPU_FLAG_RVV_I32 && vlenb >= 16) {
> #if __riscv_xlen >= 64
> if (flags & AV_CPU_FLAG_RVV_I64)
> c->vp8_luma_dc_wht = ff_vp8_luma_dc_wht_rvv;
> @@ -159,6 +168,13 @@ av_cold void ff_vp8dsp_init_riscv(VP8DSPContext *c)
> c->vp8_idct_dc_add4y = ff_vp8_idct_dc_add4y_rvv;
> if (flags & AV_CPU_FLAG_RVV_I64)
> c->vp8_idct_dc_add4uv = ff_vp8_idct_dc_add4uv_rvv;
> +
> + if (vlenb >= 32) {
> + init_loop_filter(256);
> + } else {
> + init_loop_filter(128);
> + }
> }
> +#undef init_loop_filter
> #endif
> }
> diff --git a/libavcodec/riscv/vp8dsp_rvv.S b/libavcodec/riscv/vp8dsp_rvv.S
> index 0cbf1672f7..b5f8bb31b4 100644
> --- a/libavcodec/riscv/vp8dsp_rvv.S
> +++ b/libavcodec/riscv/vp8dsp_rvv.S
> @@ -275,6 +275,93 @@ func ff_vp78_idct_dc_add4uv_rvv, zve64x
> ret
> endfunc
>
> +.macro filter_fmin len, vlen, a, f1, p0f2, q0f1
> + vsetvlstatic16 \len, \vlen
> + vsext.vf2 \q0f1, \a
> + vmin.vx \p0f2, \q0f1, a7
> + vmin.vx \q0f1, \q0f1, t3
> + vadd.vi \p0f2, \p0f2, 3
> + vadd.vi \q0f1, \q0f1, 4
> + vsra.vi \p0f2, \p0f2, 3
> + vsra.vi \f1, \q0f1, 3
vssra.vi
> + vadd.vv \p0f2, \p0f2, v8
> + vsub.vv \q0f1, v16, \f1
> + vmax.vx \p0f2, \p0f2, zero
> + vmax.vx \q0f1, \q0f1, zero
> +.endm
> +
> +.macro filter len, vlen, type, normal, inner, dst, stride, fE, fI, thresh
> +.ifc \type,v
> + slli a6, \stride, 1
> + sub t2, \dst, a6
> + add t4, \dst, \stride
> + sub t1, \dst, \stride
> + vle8.v v1, (t2)
> + vle8.v v11, (t4)
> + vle8.v v17, (t1)
> + vle8.v v22, (\dst)
> +.else
> + addi t1, \dst, -1
> + addi a6, \dst, -2
> + addi t4, \dst, 1
> + vlse8.v v1, (a6), \stride
> + vlse8.v v11, (t4), \stride
> + vlse8.v v17, (t1), \stride
> + vlse8.v v22, (\dst), \stride
vlsseg4e8.v
> +.endif
> + vwsubu.vv v12, v1, v11 // p1-q1
> + vwsubu.vv v24, v22, v17 // q0-p0
> + vnclip.wi v23, v12, 0
I can't find where VXRM is initialised for that.
> + vsetvlstatic16 \len, \vlen
> + // vp8_simple_limit(dst + i, stride, flim)
> + li a7, 2
> + vneg.v v18, v12
> + vmax.vv v18, v18, v12
> + vneg.v v8, v24
> + vmax.vv v8, v8, v24
> + vsrl.vi v18, v18, 1
> + vmacc.vx v18, a7, v8
> + vmsleu.vx v0, v18, \fE
> +
> + li t5, 3
> + li a7, 124
> + li t3, 123
> + vmul.vx v30, v24, t5
> + vsext.vf2 v4, v23
> + vzext.vf2 v8, v17 // p0
> + vzext.vf2 v16, v22 // q0
> + vadd.vv v12, v30, v4
vwadd.wv
> + vsetvlstatic8 \len, \vlen
> + vnclip.wi v11, v12, 0
> + filter_fmin \len, \vlen, v11, v24, v4, v6
> + vsetvlstatic8 \len, \vlen
> + vnclipu.wi v4, v4, 0
> + vnclipu.wi v6, v6, 0
> +
> +.ifc \type,v
> + vse8.v v4, (t1), v0.t
> + vse8.v v6, (\dst), v0.t
> +.else
> + vsse8.v v4, (t1), \stride, v0.t
> + vsse8.v v6, (\dst), \stride, v0.t
vsseg2e8.v
> +.endif
> +
> +.endm
> +
> +.irp vlen,256,128
> +func ff_vp8_v_loop_filter16_simple_rvv\vlen, zve32x
> + vsetvlstatic8 16, \vlen
> + filter 16, \vlen, v, 0, 0, a0, a1, a2, a3, a4
> + ret
> +endfunc
> +
> +func ff_vp8_h_loop_filter16_simple_rvv\vlen, zve32x
> + vsetvlstatic8 16, \vlen
> + filter 16, \vlen, h, 0, 0, a0, a1, a2, a3, a4
> + ret
> +endfunc
> +.endr
> +
> .macro bilin_load_h dst mn
> addi t5, a2, 1
> vle8.v \dst, (a2)
--
レミ・デニ-クールモン
http://www.remlab.net/
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
^ permalink raw reply [flat|nested] 4+ messages in thread
end of thread, other threads:[~2024-06-24 20:19 UTC | newest]
Thread overview: 4+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
[not found] <20240622155806.3191984-1-uk7b@foxmail.com>
2024-06-22 15:58 ` [FFmpeg-devel] [PATCH 2/4] lavc/vp8dsp: R-V V loop_filter_simple uk7b
2024-06-24 20:19 ` Rémi Denis-Courmont
2024-06-22 15:58 ` [FFmpeg-devel] [PATCH 3/4] lavc/vp8dsp: R-V V loop_filter_inner uk7b
2024-06-22 15:58 ` [FFmpeg-devel] [PATCH 4/4] lavc/vp8dsp: R-V V loop_filter uk7b
Git Inbox Mirror of the ffmpeg-devel mailing list - see https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
This inbox may be cloned and mirrored by anyone:
git clone --mirror https://master.gitmailbox.com/ffmpegdev/0 ffmpegdev/git/0.git
# If you have public-inbox 1.1+ installed, you may
# initialize and index your mirror using the following commands:
public-inbox-init -V2 ffmpegdev ffmpegdev/ https://master.gitmailbox.com/ffmpegdev \
ffmpegdev@gitmailbox.com
public-inbox-index ffmpegdev
Example config snippet for mirrors.
AGPL code for this site: git clone https://public-inbox.org/public-inbox.git