Re: [FFmpeg-devel] [PATCH v2 4/4] swscale/aarch64: add neon {lum, chr}ConvertRange

[Ramiro Polla <ramiro.polla@gmail.com>]

On Tue, Jun 18, 2024 at 7:42 PM Ramiro Polla <ramiro.polla@gmail.com> wrote:
>
> On Tue, Jun 11, 2024 at 2:29 PM Ramiro Polla <ramiro.polla@gmail.com> wrote:
> >
> > chrRangeFromJpeg_8_c: 29.2
> > chrRangeFromJpeg_8_neon: 19.5
> > chrRangeFromJpeg_24_c: 80.5
> > chrRangeFromJpeg_24_neon: 34.0
> > chrRangeFromJpeg_128_c: 413.7
> > chrRangeFromJpeg_128_neon: 156.0
> > chrRangeFromJpeg_144_c: 471.0
> > chrRangeFromJpeg_144_neon: 174.2
> > chrRangeFromJpeg_256_c: 842.0
> > chrRangeFromJpeg_256_neon: 305.5
> > chrRangeFromJpeg_512_c: 1699.0
> > chrRangeFromJpeg_512_neon: 608.0
> > chrRangeToJpeg_8_c: 51.7
> > chrRangeToJpeg_8_neon: 22.7
> > chrRangeToJpeg_24_c: 149.7
> > chrRangeToJpeg_24_neon: 38.0
> > chrRangeToJpeg_128_c: 761.7
> > chrRangeToJpeg_128_neon: 176.7
> > chrRangeToJpeg_144_c: 866.2
> > chrRangeToJpeg_144_neon: 198.7
> > chrRangeToJpeg_256_c: 1516.5
> > chrRangeToJpeg_256_neon: 348.7
> > chrRangeToJpeg_512_c: 3067.2
> > chrRangeToJpeg_512_neon: 692.7
> > lumRangeFromJpeg_8_c: 24.0
> > lumRangeFromJpeg_8_neon: 17.0
> > lumRangeFromJpeg_24_c: 56.7
> > lumRangeFromJpeg_24_neon: 21.0
> > lumRangeFromJpeg_128_c: 294.5
> > lumRangeFromJpeg_128_neon: 76.7
> > lumRangeFromJpeg_144_c: 332.5
> > lumRangeFromJpeg_144_neon: 86.7
> > lumRangeFromJpeg_256_c: 586.0
> > lumRangeFromJpeg_256_neon: 152.2
> > lumRangeFromJpeg_512_c: 1190.0
> > lumRangeFromJpeg_512_neon: 298.0
> > lumRangeToJpeg_8_c: 31.7
> > lumRangeToJpeg_8_neon: 19.5
> > lumRangeToJpeg_24_c: 83.5
> > lumRangeToJpeg_24_neon: 24.2
> > lumRangeToJpeg_128_c: 440.5
> > lumRangeToJpeg_128_neon: 91.0
> > lumRangeToJpeg_144_c: 504.2
> > lumRangeToJpeg_144_neon: 101.0
> > lumRangeToJpeg_256_c: 879.7
> > lumRangeToJpeg_256_neon: 177.2
> > lumRangeToJpeg_512_c: 1794.2
> > lumRangeToJpeg_512_neon: 354.0
> > ---
> >  libswscale/aarch64/Makefile             |  1 +
> >  libswscale/aarch64/range_convert_neon.S | 99 +++++++++++++++++++++++++
> >  libswscale/aarch64/swscale.c            | 21 ++++++
> >  libswscale/swscale_internal.h           |  1 +
> >  libswscale/utils.c                      |  4 +-
> >  5 files changed, 125 insertions(+), 1 deletion(-)
> >  create mode 100644 libswscale/aarch64/range_convert_neon.S
> >
> > diff --git a/libswscale/aarch64/Makefile b/libswscale/aarch64/Makefile
> > index adfd90a1b6..37ad960619 100644
> > --- a/libswscale/aarch64/Makefile
> > +++ b/libswscale/aarch64/Makefile
> > @@ -5,5 +5,6 @@ OBJS        += aarch64/rgb2rgb.o                \
> >  NEON-OBJS   += aarch64/hscale.o                 \
> >                 aarch64/input.o                  \
> >                 aarch64/output.o                 \
> > +               aarch64/range_convert_neon.o     \
> >                 aarch64/rgb2rgb_neon.o           \
> >                 aarch64/yuv2rgb_neon.o           \
> > diff --git a/libswscale/aarch64/range_convert_neon.S b/libswscale/aarch64/range_convert_neon.S
> > new file mode 100644
> > index 0000000000..ea56dc2e32
> > --- /dev/null
> > +++ b/libswscale/aarch64/range_convert_neon.S
> > @@ -0,0 +1,99 @@
> > +/*
> > + * Copyright (c) 2024 Ramiro Polla
> > + *
> > + * This file is part of FFmpeg.
> > + *
> > + * FFmpeg is free software; you can redistribute it and/or
> > + * modify it under the terms of the GNU Lesser General Public
> > + * License as published by the Free Software Foundation; either
> > + * version 2.1 of the License, or (at your option) any later version.
> > + *
> > + * FFmpeg is distributed in the hope that it will be useful,
> > + * but WITHOUT ANY WARRANTY; without even the implied warranty of
> > + * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
> > + * Lesser General Public License for more details.
> > + *
> > + * You should have received a copy of the GNU Lesser General Public
> > + * License along with FFmpeg; if not, write to the Free Software
> > + * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
> > + */
> > +
> > +#include "libavutil/aarch64/asm.S"
> > +
> > +.macro lumConvertRange name, max, mult, offset, shift
> > +function ff_\name, export=1
> > +.if \max != 0
> > +        mov             w3, #\max
> > +        dup             v24.8h, w3
> > +.endif
> > +        mov             w3, #\mult
> > +        dup             v25.4s, w3
> > +        movz            w3, \offset & 0xffff
> > +        movk            w3, (\offset >> 16) & 0xffff, lsl #16
> > +        dup             v26.4s, w3
> > +1:
> > +        ld1             {v0.8h}, [x0]
> > +.if \max != 0
> > +        smin            v0.8h, v0.8h, v24.8h
> > +.endif
> > +        mov             v16.16b, v26.16b
> > +        mov             v18.16b, v26.16b
> > +        sxtl            v20.4s, v0.4h
> > +        sxtl2           v22.4s, v0.8h
> > +        mla             v16.4s, v20.4s, v25.4s
> > +        mla             v18.4s, v22.4s, v25.4s
> > +        shrn            v0.4h, v16.4s, #\shift
> > +        shrn2           v0.8h, v18.4s, #\shift
> > +        subs            w1, w1, #8
> > +        st1             {v0.8h}, [x0], #16
> > +        b.gt            1b
> > +        ret
> > +endfunc
> > +.endm
> > +
> > +.macro chrConvertRange name, max, mult, offset, shift
> > +function ff_\name, export=1
> > +.if \max != 0
> > +        mov             w3, #\max
> > +        dup             v24.8h, w3
> > +.endif
> > +        mov             w3, #\mult
> > +        dup             v25.4s, w3
> > +        movz            w3, \offset & 0xffff
> > +        movk            w3, (\offset >> 16) & 0xffff, lsl #16
> > +        dup             v26.4s, w3
> > +1:
> > +        ld1             {v0.8h}, [x0]
> > +        ld1             {v1.8h}, [x1]
> > +.if \max != 0
> > +        smin            v0.8h, v0.8h, v24.8h
> > +        smin            v1.8h, v1.8h, v24.8h
> > +.endif
> > +        mov             v16.16b, v26.16b
> > +        mov             v17.16b, v26.16b
> > +        mov             v18.16b, v26.16b
> > +        mov             v19.16b, v26.16b
> > +        sxtl            v20.4s, v0.4h
> > +        sxtl            v21.4s, v1.4h
> > +        sxtl2           v22.4s, v0.8h
> > +        sxtl2           v23.4s, v1.8h
> > +        mla             v16.4s, v20.4s, v25.4s
> > +        mla             v17.4s, v21.4s, v25.4s
> > +        mla             v18.4s, v22.4s, v25.4s
> > +        mla             v19.4s, v23.4s, v25.4s
> > +        shrn            v0.4h, v16.4s, #\shift
> > +        shrn            v1.4h, v17.4s, #\shift
> > +        shrn2           v0.8h, v18.4s, #\shift
> > +        shrn2           v1.8h, v19.4s, #\shift
> > +        subs            w2, w2, #8
> > +        st1             {v0.8h}, [x0], #16
> > +        st1             {v1.8h}, [x1], #16
> > +        b.gt            1b
> > +        ret
> > +endfunc
> > +.endm
> > +
> > +lumConvertRange lumRangeToJpeg_neon,   30189, 19077, -39057361, 14
> > +chrConvertRange chrRangeToJpeg_neon,   30775,  4663,  -9289992, 12
> > +lumConvertRange lumRangeFromJpeg_neon,     0, 14071,  33561947, 14
> > +chrConvertRange chrRangeFromJpeg_neon,     0,  1799,   4081085, 11
> > diff --git a/libswscale/aarch64/swscale.c b/libswscale/aarch64/swscale.c
> > index 4c4ea39dc1..e4ea3309ba 100644
> > --- a/libswscale/aarch64/swscale.c
> > +++ b/libswscale/aarch64/swscale.c
> > @@ -215,6 +215,26 @@ void ff_rgb24ToUV_half_neon(uint8_t *_dstU, uint8_t *_dstV, const uint8_t *unuse
> >                         const uint8_t *src2, int width, uint32_t *rgb2yuv,
> >                         void *opq);
> >
> > +void ff_lumRangeFromJpeg_neon(int16_t *dst, int width);
> > +void ff_chrRangeFromJpeg_neon(int16_t *dstU, int16_t *dstV, int width);
> > +void ff_lumRangeToJpeg_neon(int16_t *dst, int width);
> > +void ff_chrRangeToJpeg_neon(int16_t *dstU, int16_t *dstV, int width);
> > +
> > +av_cold void ff_sws_init_range_convert_aarch64(SwsContext *c)
> > +{
> > +    if (c->srcRange != c->dstRange && !isAnyRGB(c->dstFormat)) {
> > +        if (c->dstBpc <= 14) {
> > +            if (c->srcRange) {
> > +                c->lumConvertRange = ff_lumRangeFromJpeg_neon;
> > +                c->chrConvertRange = ff_chrRangeFromJpeg_neon;
> > +            } else {
> > +                c->lumConvertRange = ff_lumRangeToJpeg_neon;
> > +                c->chrConvertRange = ff_chrRangeToJpeg_neon;
> > +            }
> > +        }
> > +    }
> > +}
> > +
> >  av_cold void ff_sws_init_swscale_aarch64(SwsContext *c)
> >  {
> >      int cpu_flags = av_get_cpu_flags();
> > @@ -237,5 +257,6 @@ av_cold void ff_sws_init_swscale_aarch64(SwsContext *c)
> >          default:
> >              break;
> >          }
> > +        ff_sws_init_range_convert_aarch64(c);
> >      }
> >  }
> > diff --git a/libswscale/swscale_internal.h b/libswscale/swscale_internal.h
> > index d5e7b5e71c..0818f50c7f 100644
> > --- a/libswscale/swscale_internal.h
> > +++ b/libswscale/swscale_internal.h
> > @@ -697,6 +697,7 @@ void ff_yuv2rgb_init_tables_ppc(SwsContext *c, const int inv_table[4],
> >  void ff_updateMMXDitherTables(SwsContext *c, int dstY);
> >
> >  av_cold void ff_sws_init_range_convert(SwsContext *c);
> > +av_cold void ff_sws_init_range_convert_aarch64(SwsContext *c);
> >  av_cold void ff_sws_init_range_convert_loongarch(SwsContext *c);
> >  av_cold void ff_sws_init_range_convert_x86(SwsContext *c);
> >
> > diff --git a/libswscale/utils.c b/libswscale/utils.c
> > index 8dfa57b5ff..12dba712c1 100644
> > --- a/libswscale/utils.c
> > +++ b/libswscale/utils.c
> > @@ -1080,7 +1080,9 @@ int sws_setColorspaceDetails(struct SwsContext *c, const int inv_table[4],
> >
> >      if (need_reinit) {
> >          ff_sws_init_range_convert(c);
> > -#if ARCH_LOONGARCH64
> > +#if ARCH_AARCH64
> > +        ff_sws_init_range_convert_aarch64(c);
> > +#elif ARCH_LOONGARCH64
> >          ff_sws_init_range_convert_loongarch(c);
> >  #elif ARCH_X86
> >          ff_sws_init_range_convert_x86(c);
> > --
> > 2.30.2
> >
>
> I finally tested this patch with movz/movk/dup instead of ld1 on apple
> arm. I'll apply tomorrow if there are no more comments.

Reviewed by Martin on IRC and pushed.
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel

To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".