From: "Rémi Denis-Courmont" <remi@remlab.net>
To: ffmpeg-devel@ffmpeg.org
Subject: [FFmpeg-devel] [PATCH 5/5] lavc/h264dsp: R-V V 8-bit h264_idct8_add
Date: Wed, 3 Jul 2024 20:09:57 +0300
Message-ID: <20240703170957.17063-1-remi@remlab.net> (raw)
In-Reply-To: <20240702171336.26390-1-remi@remlab.net>
T-Head C908 (cycles):
h264_idct8_add_8bpp_c: 1072.0
h264_idct8_add_8bpp_rvv_i32: 318.5
---
libavcodec/riscv/h264dsp_init.c | 2 +
libavcodec/riscv/h264idct_rvv.S | 137 +++++++++++++++++++++++++++++++-
2 files changed, 138 insertions(+), 1 deletion(-)
diff --git a/libavcodec/riscv/h264dsp_init.c b/libavcodec/riscv/h264dsp_init.c
index f78ca3ea05..bf9743eb6b 100644
--- a/libavcodec/riscv/h264dsp_init.c
+++ b/libavcodec/riscv/h264dsp_init.c
@@ -35,6 +35,7 @@ void ff_h264_h_loop_filter_luma_mbaff_8_rvv(uint8_t *pix, ptrdiff_t stride,
int alpha, int beta, int8_t *tc0);
void ff_h264_idct_add_8_rvv(uint8_t *dst, int16_t *block, int stride);
+void ff_h264_idct8_add_8_rvv(uint8_t *dst, int16_t *block, int stride);
void ff_h264_idct_add16_8_rvv(uint8_t *dst, const int *blockoffset,
int16_t *block, int stride,
const uint8_t nnzc[5 * 8]);
@@ -65,6 +66,7 @@ av_cold void ff_h264dsp_init_riscv(H264DSPContext *dsp, const int bit_depth,
ff_h264_h_loop_filter_luma_mbaff_8_rvv;
dsp->h264_idct_add = ff_h264_idct_add_8_rvv;
+ dsp->h264_idct8_add = ff_h264_idct8_add_8_rvv;
# if __riscv_xlen == 64
dsp->h264_idct_add16 = ff_h264_idct_add16_8_rvv;
dsp->h264_idct_add16intra = ff_h264_idct_add16intra_8_rvv;
diff --git a/libavcodec/riscv/h264idct_rvv.S b/libavcodec/riscv/h264idct_rvv.S
index b36a7f7572..5dd55085bc 100644
--- a/libavcodec/riscv/h264idct_rvv.S
+++ b/libavcodec/riscv/h264idct_rvv.S
@@ -103,6 +103,140 @@ func ff_h264_idct_add_8_rvv, zve32x
ret
endfunc
+ .variant_cc ff_h264_idct8_rvv
+func ff_h264_idct8_rvv, zve32x
+ vsra.vi v9, v7, 1
+ vsra.vi v11, v3, 1
+ vsra.vi v12, v2, 1
+ vsra.vi v13, v5, 1
+ vsra.vi v14, v6, 1
+ vsra.vi v15, v1, 1
+ vadd.vv v9, v3, v9
+ vsub.vv v11, v1, v11
+ vsub.vv v13, v13, v1
+ vadd.vv v15, v3, v15
+ vsub.vv v9, v5, v9
+ vadd.vv v11, v11, v7
+ vadd.vv v13, v13, v7
+ vadd.vv v15, v15, v5
+ vadd.vv v8, v0, v4 # a0
+ vsub.vv v9, v9, v7 # a1
+ vsub.vv v10, v0, v4 # a2
+ vsub.vv v11, v11, v3 # a3
+ vsub.vv v12, v12, v6 # a4
+ vadd.vv v13, v13, v5 # a5
+ vadd.vv v14, v14, v2 # a6
+ vadd.vv v15, v15, v1 # a7
+# 8-15
+ vsra.vi v7, v9, 2
+ vsra.vi v5, v11, 2
+ vsra.vi v3, v13, 2
+ vsra.vi v1, v15, 2
+# 1,3,5,7,8-15 free: 0,2,4,6
+ vadd.vv v0, v8, v14 # b0
+ vadd.vv v6, v10, v12 # b2
+ vsub.vv v2, v10, v12 # b4
+ vsub.vv v4, v8, v14 # b6
+# 0-7,9,11,13,15 free: 8,10,12,14
+ vsub.vv v8, v15, v7 # b7
+ vsub.vv v14, v5, v13 # b5
+ vadd.vv v12, v1, v9 # b1
+ vadd.vv v10, v11, v3 # b3
+ vadd.vv v1, v6, v14
+ vsub.vv v6, v6, v14
+ vsub.vv v7, v0, v8
+ vadd.vv v0, v0, v8
+ vsub.vv v5, v2, v10
+ vadd.vv v2, v2, v10
+ vadd.vv v3, v4, v12
+ vsub.vv v4, v4, v12
+ jr t0
+endfunc
+
+func ff_h264_idct8_add_8_rvv, zve32x
+ csrwi vxrm, 0
+.Lidct8_add_8_rvv:
+ vsetivli zero, 8, e16, m1, ta, ma
+ addi t1, a1, 1 * 8 * 2
+ vle16.v v0, (a1)
+ addi t2, a1, 2 * 8 * 2
+ vle16.v v1, (t1)
+ addi t3, a1, 3 * 8 * 2
+ vle16.v v2, (t2)
+ addi t4, a1, 4 * 8 * 2
+ vle16.v v3, (t3)
+ addi t5, a1, 5 * 8 * 2
+ vle16.v v4, (t4)
+ addi t6, a1, 6 * 8 * 2
+ vle16.v v5, (t5)
+ addi a7, a1, 7 * 8 * 2
+ vle16.v v6, (t6)
+ vle16.v v7, (a7)
+ jal t0, ff_h264_idct8_rvv
+ vse16.v v0, (a1)
+ vse16.v v1, (t1)
+ vse16.v v2, (t2)
+ vse16.v v3, (t3)
+ vse16.v v4, (t4)
+ vse16.v v5, (t5)
+ vse16.v v6, (t6)
+ vse16.v v7, (a7)
+ vlseg8e16.v v0, (a1)
+ .rept 1024 / __riscv_xlen
+ sx zero, ((__riscv_xlen / 8) * \+)(a1)
+ .endr
+ jal t0, ff_h264_idct8_rvv
+ add t1, a0, a2
+ vle8.v v16, (a0)
+ add t2, t1, a2
+ vle8.v v17, (t1)
+ add t3, t2, a2
+ vle8.v v18, (t2)
+ add t4, t3, a2
+ vle8.v v19, (t3)
+ add t5, t4, a2
+ vle8.v v20, (t4)
+ add t6, t5, a2
+ vle8.v v21, (t5)
+ add a7, t6, a2
+ vle8.v v22, (t6)
+ vle8.v v23, (a7)
+ .irp n,0,1,2,3,4,5,6,7
+ vssra.vi v\n, v\n, 6
+ .endr
+ vsetvli zero, zero, e8, mf2, ta, ma
+ vwaddu.wv v0, v0, v16
+ vwaddu.wv v1, v1, v17
+ vwaddu.wv v2, v2, v18
+ vwaddu.wv v3, v3, v19
+ vwaddu.wv v4, v4, v20
+ vwaddu.wv v5, v5, v21
+ vwaddu.wv v6, v6, v22
+ vwaddu.wv v7, v7, v23
+ vsetvli zero, zero, e16, m1, ta, ma
+ .irp n,0,1,2,3,4,5,6,7
+ vmax.vx v\n, v\n, zero
+ .endr
+ vsetvli zero, zero, e8, mf2, ta, ma
+ vnclipu.wi v16, v0, 0
+ vnclipu.wi v17, v1, 0
+ vnclipu.wi v18, v2, 0
+ vnclipu.wi v19, v3, 0
+ vnclipu.wi v20, v4, 0
+ vnclipu.wi v21, v5, 0
+ vnclipu.wi v22, v6, 0
+ vnclipu.wi v23, v7, 0
+ vse8.v v16, (a0)
+ vse8.v v17, (t1)
+ vse8.v v18, (t2)
+ vse8.v v19, (t3)
+ vse8.v v20, (t4)
+ vse8.v v21, (t5)
+ vse8.v v22, (t6)
+ vse8.v v23, (a7)
+ ret
+endfunc
+
const ff_h264_scan8
.byte 014, 015, 024, 025, 016, 017, 026, 027
.byte 034, 035, 044, 045, 036, 037, 046, 047
@@ -251,6 +385,7 @@ func ff_h264_idct_add16intra_\depth\()_rvv, zve32x
endfunc
func ff_h264_idct8_add4_\depth\()_rvv, zve32x
+ csrwi vxrm, 0
addi sp, sp, -80
lla t0, ff_h264_scan8
sd s0, (sp)
@@ -300,7 +435,7 @@ func ff_h264_idct8_add4_\depth\()_rvv, zve32x
call ff_h264_idct8_dc_add_\depth\()_c
j 3f
2:
- call ff_h264_idct8_add_\depth\()_c
+ call .Lidct8_add_\depth\()_rvv
3:
srli s3, s3, 1
addi s5, s5, 4 * 4
--
2.45.2
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
prev parent reply other threads:[~2024-07-03 17:10 UTC|newest]
Thread overview: 6+ messages / expand[flat|nested] mbox.gz Atom feed top
2024-07-02 17:13 [FFmpeg-devel] [PATCH 1/3] lavc/h264dsp: R-V V 8-bit h264_idct_add16 Rémi Denis-Courmont
2024-07-02 17:13 ` [FFmpeg-devel] [PATCH 2/3] lavc/h264dsp: R-V V 8-bit h264_idct_add16intra Rémi Denis-Courmont
2024-07-02 17:13 ` [FFmpeg-devel] [PATCH 3/3] lavc/h264dsp: R-V V 8-bit h264_idct8_add4 Rémi Denis-Courmont
2024-07-02 17:27 ` [FFmpeg-devel] [PATCH 1/3] lavc/h264dsp: R-V V 8-bit h264_idct_add16 Rémi Denis-Courmont
2024-07-02 19:22 ` [FFmpeg-devel] [PATCH 4/4] lavc/h264dsp: R-V V 8-bit h264_idct_add Rémi Denis-Courmont
2024-07-03 17:09 ` Rémi Denis-Courmont [this message]
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20240703170957.17063-1-remi@remlab.net \
--to=remi@remlab.net \
--cc=ffmpeg-devel@ffmpeg.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Git Inbox Mirror of the ffmpeg-devel mailing list - see https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
This inbox may be cloned and mirrored by anyone:
git clone --mirror https://master.gitmailbox.com/ffmpegdev/0 ffmpegdev/git/0.git
# If you have public-inbox 1.1+ installed, you may
# initialize and index your mirror using the following commands:
public-inbox-init -V2 ffmpegdev ffmpegdev/ https://master.gitmailbox.com/ffmpegdev \
ffmpegdev@gitmailbox.com
public-inbox-index ffmpegdev
Example config snippet for mirrors.
AGPL code for this site: git clone https://public-inbox.org/public-inbox.git