* [FFmpeg-devel] [PATCH 1/2] lavc/vc1dsp: fix potential overflow in R-V V inv_trans_4
@ 2024-06-30 9:04 Rémi Denis-Courmont
2024-06-30 9:04 ` [FFmpeg-devel] [PATCH 2/2] lavc/h264dsp: R-V V 8-bit luma loop filter Rémi Denis-Courmont
0 siblings, 1 reply; 4+ messages in thread
From: Rémi Denis-Courmont @ 2024-06-30 9:04 UTC (permalink / raw)
To: ffmpeg-devel
Judging by the coefficients, the last round of add/sub can overflow
to 17 bits with a very small probability just as with the 8-point
transform. This is not observed under FATE, but better safe than sorry.
---
libavcodec/riscv/vc1dsp_rvv.S | 15 ++++++++-------
1 file changed, 8 insertions(+), 7 deletions(-)
diff --git a/libavcodec/riscv/vc1dsp_rvv.S b/libavcodec/riscv/vc1dsp_rvv.S
index fa4bef2b8b..bf7864227a 100644
--- a/libavcodec/riscv/vc1dsp_rvv.S
+++ b/libavcodec/riscv/vc1dsp_rvv.S
@@ -202,13 +202,14 @@ func ff_vc1_inv_trans_4_rvv, zve32x
vmul.vx v20, v1, t2
vadd.vv v26, v14, v16 # t3
vsub.vv v27, v18, v20 # t4
- vadd.vv v0, v24, v26
- vsub.vv v1, v25, v27
- vadd.vv v2, v25, v27
- vsub.vv v3, v24, v26
- .irp n,0,1,2,3
- vssra.vx v\n, v\n, t1 # + 4 >> 3 or + 64 >> 7
- .endr
+ vwadd.vv v8, v24, v26
+ vwsub.vv v10, v25, v27
+ vwadd.vv v12, v25, v27
+ vwsub.vv v14, v24, v26
+ vnclip.wx v0, v8, t1
+ vnclip.wx v1, v10, t1
+ vnclip.wx v2, v12, t1
+ vnclip.wx v3, v14, t1
jr t0
endfunc
--
2.45.2
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
^ permalink raw reply [flat|nested] 4+ messages in thread
* [FFmpeg-devel] [PATCH 2/2] lavc/h264dsp: R-V V 8-bit luma loop filter
2024-06-30 9:04 [FFmpeg-devel] [PATCH 1/2] lavc/vc1dsp: fix potential overflow in R-V V inv_trans_4 Rémi Denis-Courmont
@ 2024-06-30 9:04 ` Rémi Denis-Courmont
2024-06-30 9:05 ` Rémi Denis-Courmont
2024-07-01 13:33 ` flow gg
0 siblings, 2 replies; 4+ messages in thread
From: Rémi Denis-Courmont @ 2024-06-30 9:04 UTC (permalink / raw)
To: ffmpeg-devel
T-Head C908 (cycles):
h264_h_loop_filter_luma_8bpp_c: 297.5
h264_h_loop_filter_luma_8bpp_rvv_i32: 374.7
h264_v_loop_filter_luma_8bpp_c: 862.7
h264_v_loop_filter_luma_8bpp_rvv_i32: 200.7
Performance in the horizontal scenario seems worse than scalar. x86
SSE2 and AVX optimisations are similarly affected. This is presumably
caused by unlucky inputs from checkasm, such that the C code
short-circuits almost all filter calculations.
---
libavcodec/riscv/Makefile | 1 +
libavcodec/riscv/h264dsp_init.c | 13 ++-
libavcodec/riscv/h264dsp_rvv.S | 136 ++++++++++++++++++++++++++++++++
3 files changed, 149 insertions(+), 1 deletion(-)
create mode 100644 libavcodec/riscv/h264dsp_rvv.S
diff --git a/libavcodec/riscv/Makefile b/libavcodec/riscv/Makefile
index c180223141..a1510e8c6e 100644
--- a/libavcodec/riscv/Makefile
+++ b/libavcodec/riscv/Makefile
@@ -31,6 +31,7 @@ RVV-OBJS-$(CONFIG_H263DSP) += riscv/h263dsp_rvv.o
OBJS-$(CONFIG_H264CHROMA) += riscv/h264_chroma_init_riscv.o
RVV-OBJS-$(CONFIG_H264CHROMA) += riscv/h264_mc_chroma.o
OBJS-$(CONFIG_H264DSP) += riscv/h264dsp_init.o
+RVV-OBJS-$(CONFIG_H264DSP) += riscv/h264dsp_rvv.o
OBJS-$(CONFIG_HUFFYUV_DECODER) += riscv/huffyuvdsp_init.o
RVV-OBJS-$(CONFIG_HUFFYUV_DECODER) += riscv/huffyuvdsp_rvv.o
OBJS-$(CONFIG_IDCTDSP) += riscv/idctdsp_init.o
diff --git a/libavcodec/riscv/h264dsp_init.c b/libavcodec/riscv/h264dsp_init.c
index dbbf3db400..0d4d541992 100644
--- a/libavcodec/riscv/h264dsp_init.c
+++ b/libavcodec/riscv/h264dsp_init.c
@@ -24,8 +24,14 @@
#include "libavutil/attributes.h"
#include "libavutil/cpu.h"
+#include "libavutil/riscv/cpu.h"
#include "libavcodec/h264dsp.h"
+void ff_h264_v_loop_filter_luma_8_rvv(uint8_t *pix, ptrdiff_t stride,
+ int alpha, int beta, int8_t *tc0);
+void ff_h264_h_loop_filter_luma_8_rvv(uint8_t *pix, ptrdiff_t stride,
+ int alpha, int beta, int8_t *tc0);
+
extern int ff_startcode_find_candidate_rvb(const uint8_t *, int);
extern int ff_startcode_find_candidate_rvv(const uint8_t *, int);
@@ -38,8 +44,13 @@ av_cold void ff_h264dsp_init_riscv(H264DSPContext *dsp, const int bit_depth,
if (flags & AV_CPU_FLAG_RVB_BASIC)
dsp->startcode_find_candidate = ff_startcode_find_candidate_rvb;
# if HAVE_RVV
- if (flags & AV_CPU_FLAG_RVV_I32)
+ if (flags & AV_CPU_FLAG_RVV_I32) {
+ if (bit_depth == 8 && ff_rv_vlen_least(128)) {
+ dsp->h264_v_loop_filter_luma = ff_h264_v_loop_filter_luma_8_rvv;
+ dsp->h264_h_loop_filter_luma = ff_h264_h_loop_filter_luma_8_rvv;
+ }
dsp->startcode_find_candidate = ff_startcode_find_candidate_rvv;
+ }
# endif
#endif
}
diff --git a/libavcodec/riscv/h264dsp_rvv.S b/libavcodec/riscv/h264dsp_rvv.S
new file mode 100644
index 0000000000..ea9dfb1a7e
--- /dev/null
+++ b/libavcodec/riscv/h264dsp_rvv.S
@@ -0,0 +1,136 @@
+/*
+ * Copyright © 2024 Rémi Denis-Courmont.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions are met:
+ *
+ * 1. Redistributions of source code must retain the above copyright notice,
+ * this list of conditions and the following disclaimer.
+ *
+ * 2. Redistributions in binary form must reproduce the above copyright notice,
+ * this list of conditions and the following disclaimer in the documentation
+ * and/or other materials provided with the distribution.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
+ * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
+ * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
+ * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
+ * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
+ * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
+ * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ */
+
+#include "libavutil/riscv/asm.S"
+
+ .variant_cc ff_h264_loop_filter_luma_8_rvv
+func ff_h264_loop_filter_luma_8_rvv, zve32x
+ # p2: v8, p1: v9, p0: v10, q0: v11, q1: v12, q2: v13
+ # alpha: a2, beta: a3
+ csrwi vxrm, 0
+ vid.v v0
+ vaaddu.vv v14, v10, v11 # (p0 + q0 + 1) / 2
+ vsrl.vi v0, v0, 2 # v0[i] = i / inner_iters
+ vwsubu.vv v16, v9, v12
+ vrgather.vv v6, v4, v0 # tc_orig
+ vwaddu.vv v18, v8, v14
+ vwaddu.vv v20, v13, v14
+ vnsra.wi v24, v16, 2 # (p1 - q1) / 4
+ vnsrl.wi v14, v18, 1
+ vnsrl.wi v15, v20, 1
+ vneg.v v5, v6 # -tc_orig
+ vwsubu.vv v22, v11, v10 # q0 - p0
+ vwsubu.vv v18, v14, v9
+ vwsubu.vv v20, v15, v12
+ vwadd.wv v16, v22, v24
+ vmsge.vi v7, v6, 0 # tc_orig >= 0
+ vnclip.wi v14, v18, 0
+ vnclip.wi v15, v20, 0
+ vnclip.wi v16, v16, 1 # clip8((q0 - p0 + (p1 - q1) / 4 + 1) >> 1)
+ vmin.vv v14, v14, v6
+ vmin.vv v15, v15, v6
+ vmax.vv v14, v14, v5 # clip(p2 + ... - p1, +/-tc_orig)
+ vmax.vv v15, v15, v5 # clip(q2 + ... - q1, +/-tc_orig)
+ vwsubu.vv v20, v10, v11
+ vwsubu.vv v24, v9, v10
+ vwsubu.vv v26, v10, v9
+ vwsubu.vv v28, v12, v11
+ vwsubu.vv v30, v11, v12
+ vwsubu.vv v0, v8, v10
+ vwsubu.vv v2, v10, v8
+ vwsubu.vv v4, v13, v11
+ vwsubu.vv v18, v11, v13
+ vsetvli zero, zero, e16, m2, ta, ma
+ vmax.vv v20, v20, v22 # abs(p0 - q0)
+ vmax.vv v24, v24, v26 # abs(p1 - p0)
+ vmax.vv v28, v28, v30 # abs(q1 - q0)
+ vmax.vv v22, v0, v2 # abs(p2 - p0)
+ vmax.vv v26, v4, v18 # abs(q2 - q0)
+ vmslt.vx v1, v20, a2
+ vmslt.vx v2, v24, a3
+ vmand.mm v7, v7, v1
+ vmslt.vx v3, v28, a3
+ vmand.mm v7, v7, v2
+ vmslt.vx v0, v22, a3
+ vmand.mm v7, v7, v3 # whether to update p0 and q0
+ vmslt.vx v1, v26, a3
+ vmand.mm v0, v0, v7
+ vsetvli zero, zero, e8, m1, ta, mu
+ vadd.vi v6, v6, 1, v0.t # tc++
+ vadd.vv v9, v9, v14, v0.t # p1'
+ vmand.mm v0, v1, v7
+ vadd.vi v6, v6, 1, v0.t # tc++
+ vadd.vv v12, v12, v15, v0.t # q1'
+ vneg.v v5, v6 # -tc
+ vmin.vv v16, v16, v6
+ vwcvtu.x.x.v v18, v10
+ vmax.vv v16, v16, v5
+ vwcvtu.x.x.v v20, v11
+ vwadd.wv v18, v18, v16
+ vwsub.wv v20, v20, v16
+ vmmv.m v0, v7
+ vsetvli zero, zero, e16, m2, ta, ma
+ vmax.vx v18, v18, zero
+ vmax.vx v20, v20, zero
+ vsetvli zero, zero, e8, m1, ta, mu
+ vnclipu.wi v10, v18, 0, v0.t # p0'
+ vnclipu.wi v11, v20, 0, v0.t # q0'
+ jr t0
+endfunc
+
+func ff_h264_v_loop_filter_luma_8_rvv, zve32x
+ vsetivli zero, 4, e8, mf4, ta, ma
+ vle8.v v4, (a4)
+ sub t3, a0, a1
+ vsetivli zero, 16, e8, m1, ta, ma
+ vle8.v v11, (a0)
+ sub t2, t3, a1
+ vle8.v v10, (t3)
+ sub t1, t2, a1
+ vle8.v v9, (t2)
+ add t5, a0, a1
+ vle8.v v8, (t1)
+ add t6, t5, a1
+ vle8.v v12, (t5)
+ vle8.v v13, (t6)
+ jal t0, ff_h264_loop_filter_luma_8_rvv
+ vse8.v v9, (t2)
+ vse8.v v10, (t3)
+ vse8.v v11, (a0)
+ vse8.v v12, (t5)
+ ret
+endfunc
+
+func ff_h264_h_loop_filter_luma_8_rvv, zve32x
+ vsetivli zero, 4, e8, mf4, ta, ma
+ vle8.v v4, (a4)
+ addi a0, a0, -3
+ vsetivli zero, 16, e8, m1, ta, ma
+ vlsseg6e8.v v8, (a0), a1
+ jal t0, ff_h264_loop_filter_luma_8_rvv
+ vssseg6e8.v v8, (a0), a1
+ ret
+endfunc
--
2.45.2
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
^ permalink raw reply [flat|nested] 4+ messages in thread
* Re: [FFmpeg-devel] [PATCH 2/2] lavc/h264dsp: R-V V 8-bit luma loop filter
2024-06-30 9:04 ` [FFmpeg-devel] [PATCH 2/2] lavc/h264dsp: R-V V 8-bit luma loop filter Rémi Denis-Courmont
@ 2024-06-30 9:05 ` Rémi Denis-Courmont
2024-07-01 13:33 ` flow gg
1 sibling, 0 replies; 4+ messages in thread
From: Rémi Denis-Courmont @ 2024-06-30 9:05 UTC (permalink / raw)
To: ffmpeg-devel
Disregard, botched send-email.
--
レミ・デニ-クールモン
http://www.remlab.net/
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
^ permalink raw reply [flat|nested] 4+ messages in thread
* Re: [FFmpeg-devel] [PATCH 2/2] lavc/h264dsp: R-V V 8-bit luma loop filter
2024-06-30 9:04 ` [FFmpeg-devel] [PATCH 2/2] lavc/h264dsp: R-V V 8-bit luma loop filter Rémi Denis-Courmont
2024-06-30 9:05 ` Rémi Denis-Courmont
@ 2024-07-01 13:33 ` flow gg
1 sibling, 0 replies; 4+ messages in thread
From: flow gg @ 2024-07-01 13:33 UTC (permalink / raw)
To: FFmpeg development discussions and patches
The loop filter horizontal in vp8 also has this issue ..
Rémi Denis-Courmont <remi@remlab.net> 于2024年6月30日周日 17:04写道：
> T-Head C908 (cycles):
> h264_h_loop_filter_luma_8bpp_c: 297.5
> h264_h_loop_filter_luma_8bpp_rvv_i32: 374.7
> h264_v_loop_filter_luma_8bpp_c: 862.7
> h264_v_loop_filter_luma_8bpp_rvv_i32: 200.7
>
> Performance in the horizontal scenario seems worse than scalar. x86
> SSE2 and AVX optimisations are similarly affected. This is presumably
> caused by unlucky inputs from checkasm, such that the C code
> short-circuits almost all filter calculations.
> ---
> libavcodec/riscv/Makefile | 1 +
> libavcodec/riscv/h264dsp_init.c | 13 ++-
> libavcodec/riscv/h264dsp_rvv.S | 136 ++++++++++++++++++++++++++++++++
> 3 files changed, 149 insertions(+), 1 deletion(-)
> create mode 100644 libavcodec/riscv/h264dsp_rvv.S
>
> diff --git a/libavcodec/riscv/Makefile b/libavcodec/riscv/Makefile
> index c180223141..a1510e8c6e 100644
> --- a/libavcodec/riscv/Makefile
> +++ b/libavcodec/riscv/Makefile
> @@ -31,6 +31,7 @@ RVV-OBJS-$(CONFIG_H263DSP) += riscv/h263dsp_rvv.o
> OBJS-$(CONFIG_H264CHROMA) += riscv/h264_chroma_init_riscv.o
> RVV-OBJS-$(CONFIG_H264CHROMA) += riscv/h264_mc_chroma.o
> OBJS-$(CONFIG_H264DSP) += riscv/h264dsp_init.o
> +RVV-OBJS-$(CONFIG_H264DSP) += riscv/h264dsp_rvv.o
> OBJS-$(CONFIG_HUFFYUV_DECODER) += riscv/huffyuvdsp_init.o
> RVV-OBJS-$(CONFIG_HUFFYUV_DECODER) += riscv/huffyuvdsp_rvv.o
> OBJS-$(CONFIG_IDCTDSP) += riscv/idctdsp_init.o
> diff --git a/libavcodec/riscv/h264dsp_init.c
> b/libavcodec/riscv/h264dsp_init.c
> index dbbf3db400..0d4d541992 100644
> --- a/libavcodec/riscv/h264dsp_init.c
> +++ b/libavcodec/riscv/h264dsp_init.c
> @@ -24,8 +24,14 @@
>
> #include "libavutil/attributes.h"
> #include "libavutil/cpu.h"
> +#include "libavutil/riscv/cpu.h"
> #include "libavcodec/h264dsp.h"
>
> +void ff_h264_v_loop_filter_luma_8_rvv(uint8_t *pix, ptrdiff_t stride,
> + int alpha, int beta, int8_t *tc0);
> +void ff_h264_h_loop_filter_luma_8_rvv(uint8_t *pix, ptrdiff_t stride,
> + int alpha, int beta, int8_t *tc0);
> +
> extern int ff_startcode_find_candidate_rvb(const uint8_t *, int);
> extern int ff_startcode_find_candidate_rvv(const uint8_t *, int);
>
> @@ -38,8 +44,13 @@ av_cold void ff_h264dsp_init_riscv(H264DSPContext *dsp,
> const int bit_depth,
> if (flags & AV_CPU_FLAG_RVB_BASIC)
> dsp->startcode_find_candidate = ff_startcode_find_candidate_rvb;
> # if HAVE_RVV
> - if (flags & AV_CPU_FLAG_RVV_I32)
> + if (flags & AV_CPU_FLAG_RVV_I32) {
> + if (bit_depth == 8 && ff_rv_vlen_least(128)) {
> + dsp->h264_v_loop_filter_luma =
> ff_h264_v_loop_filter_luma_8_rvv;
> + dsp->h264_h_loop_filter_luma =
> ff_h264_h_loop_filter_luma_8_rvv;
> + }
> dsp->startcode_find_candidate = ff_startcode_find_candidate_rvv;
> + }
> # endif
> #endif
> }
> diff --git a/libavcodec/riscv/h264dsp_rvv.S
> b/libavcodec/riscv/h264dsp_rvv.S
> new file mode 100644
> index 0000000000..ea9dfb1a7e
> --- /dev/null
> +++ b/libavcodec/riscv/h264dsp_rvv.S
> @@ -0,0 +1,136 @@
> +/*
> + * Copyright © 2024 Rémi Denis-Courmont.
> + *
> + * Redistribution and use in source and binary forms, with or without
> + * modification, are permitted provided that the following conditions are
> met:
> + *
> + * 1. Redistributions of source code must retain the above copyright
> notice,
> + * this list of conditions and the following disclaimer.
> + *
> + * 2. Redistributions in binary form must reproduce the above copyright
> notice,
> + * this list of conditions and the following disclaimer in the
> documentation
> + * and/or other materials provided with the distribution.
> + *
> + * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
> "AS IS"
> + * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
> THE
> + * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
> PURPOSE
> + * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS
> BE
> + * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
> + * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
> + * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR
> BUSINESS
> + * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
> + * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
> + * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF
> THE
> + * POSSIBILITY OF SUCH DAMAGE.
> + */
> +
> +#include "libavutil/riscv/asm.S"
> +
> + .variant_cc ff_h264_loop_filter_luma_8_rvv
> +func ff_h264_loop_filter_luma_8_rvv, zve32x
> + # p2: v8, p1: v9, p0: v10, q0: v11, q1: v12, q2: v13
> + # alpha: a2, beta: a3
> + csrwi vxrm, 0
> + vid.v v0
> + vaaddu.vv v14, v10, v11 # (p0 + q0 + 1) / 2
> + vsrl.vi v0, v0, 2 # v0[i] = i / inner_iters
> + vwsubu.vv v16, v9, v12
> + vrgather.vv v6, v4, v0 # tc_orig
> + vwaddu.vv v18, v8, v14
> + vwaddu.vv v20, v13, v14
> + vnsra.wi v24, v16, 2 # (p1 - q1) / 4
> + vnsrl.wi v14, v18, 1
> + vnsrl.wi v15, v20, 1
> + vneg.v v5, v6 # -tc_orig
> + vwsubu.vv v22, v11, v10 # q0 - p0
> + vwsubu.vv v18, v14, v9
> + vwsubu.vv v20, v15, v12
> + vwadd.wv v16, v22, v24
> + vmsge.vi v7, v6, 0 # tc_orig >= 0
> + vnclip.wi v14, v18, 0
> + vnclip.wi v15, v20, 0
> + vnclip.wi v16, v16, 1 # clip8((q0 - p0 + (p1 - q1) / 4 + 1)
> >> 1)
> + vmin.vv v14, v14, v6
> + vmin.vv v15, v15, v6
> + vmax.vv v14, v14, v5 # clip(p2 + ... - p1, +/-tc_orig)
> + vmax.vv v15, v15, v5 # clip(q2 + ... - q1, +/-tc_orig)
> + vwsubu.vv v20, v10, v11
> + vwsubu.vv v24, v9, v10
> + vwsubu.vv v26, v10, v9
> + vwsubu.vv v28, v12, v11
> + vwsubu.vv v30, v11, v12
> + vwsubu.vv v0, v8, v10
> + vwsubu.vv v2, v10, v8
> + vwsubu.vv v4, v13, v11
> + vwsubu.vv v18, v11, v13
> + vsetvli zero, zero, e16, m2, ta, ma
> + vmax.vv v20, v20, v22 # abs(p0 - q0)
> + vmax.vv v24, v24, v26 # abs(p1 - p0)
> + vmax.vv v28, v28, v30 # abs(q1 - q0)
> + vmax.vv v22, v0, v2 # abs(p2 - p0)
> + vmax.vv v26, v4, v18 # abs(q2 - q0)
> + vmslt.vx v1, v20, a2
> + vmslt.vx v2, v24, a3
> + vmand.mm v7, v7, v1
> + vmslt.vx v3, v28, a3
> + vmand.mm v7, v7, v2
> + vmslt.vx v0, v22, a3
> + vmand.mm v7, v7, v3 # whether to update p0 and q0
> + vmslt.vx v1, v26, a3
> + vmand.mm v0, v0, v7
> + vsetvli zero, zero, e8, m1, ta, mu
> + vadd.vi v6, v6, 1, v0.t # tc++
> + vadd.vv v9, v9, v14, v0.t # p1'
> + vmand.mm v0, v1, v7
> + vadd.vi v6, v6, 1, v0.t # tc++
> + vadd.vv v12, v12, v15, v0.t # q1'
> + vneg.v v5, v6 # -tc
> + vmin.vv v16, v16, v6
> + vwcvtu.x.x.v v18, v10
> + vmax.vv v16, v16, v5
> + vwcvtu.x.x.v v20, v11
> + vwadd.wv v18, v18, v16
> + vwsub.wv v20, v20, v16
> + vmmv.m v0, v7
> + vsetvli zero, zero, e16, m2, ta, ma
> + vmax.vx v18, v18, zero
> + vmax.vx v20, v20, zero
> + vsetvli zero, zero, e8, m1, ta, mu
> + vnclipu.wi v10, v18, 0, v0.t # p0'
> + vnclipu.wi v11, v20, 0, v0.t # q0'
> + jr t0
> +endfunc
> +
> +func ff_h264_v_loop_filter_luma_8_rvv, zve32x
> + vsetivli zero, 4, e8, mf4, ta, ma
> + vle8.v v4, (a4)
> + sub t3, a0, a1
> + vsetivli zero, 16, e8, m1, ta, ma
> + vle8.v v11, (a0)
> + sub t2, t3, a1
> + vle8.v v10, (t3)
> + sub t1, t2, a1
> + vle8.v v9, (t2)
> + add t5, a0, a1
> + vle8.v v8, (t1)
> + add t6, t5, a1
> + vle8.v v12, (t5)
> + vle8.v v13, (t6)
> + jal t0, ff_h264_loop_filter_luma_8_rvv
> + vse8.v v9, (t2)
> + vse8.v v10, (t3)
> + vse8.v v11, (a0)
> + vse8.v v12, (t5)
> + ret
> +endfunc
> +
> +func ff_h264_h_loop_filter_luma_8_rvv, zve32x
> + vsetivli zero, 4, e8, mf4, ta, ma
> + vle8.v v4, (a4)
> + addi a0, a0, -3
> + vsetivli zero, 16, e8, m1, ta, ma
> + vlsseg6e8.v v8, (a0), a1
> + jal t0, ff_h264_loop_filter_luma_8_rvv
> + vssseg6e8.v v8, (a0), a1
> + ret
> +endfunc
> --
> 2.45.2
>
> _______________________________________________
> ffmpeg-devel mailing list
> ffmpeg-devel@ffmpeg.org
> https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
>
> To unsubscribe, visit link above, or email
> ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
>
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
^ permalink raw reply [flat|nested] 4+ messages in thread
end of thread, other threads:[~2024-07-01 13:33 UTC | newest]
Thread overview: 4+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2024-06-30 9:04 [FFmpeg-devel] [PATCH 1/2] lavc/vc1dsp: fix potential overflow in R-V V inv_trans_4 Rémi Denis-Courmont
2024-06-30 9:04 ` [FFmpeg-devel] [PATCH 2/2] lavc/h264dsp: R-V V 8-bit luma loop filter Rémi Denis-Courmont
2024-06-30 9:05 ` Rémi Denis-Courmont
2024-07-01 13:33 ` flow gg
Git Inbox Mirror of the ffmpeg-devel mailing list - see https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
This inbox may be cloned and mirrored by anyone:
git clone --mirror https://master.gitmailbox.com/ffmpegdev/0 ffmpegdev/git/0.git
# If you have public-inbox 1.1+ installed, you may
# initialize and index your mirror using the following commands:
public-inbox-init -V2 ffmpegdev ffmpegdev/ https://master.gitmailbox.com/ffmpegdev \
ffmpegdev@gitmailbox.com
public-inbox-index ffmpegdev
Example config snippet for mirrors.
AGPL code for this site: git clone https://public-inbox.org/public-inbox.git