From: "Martin Storsjö" <martin@martin.st>
To: ffmpeg-devel@ffmpeg.org
Cc: Logan Lyu <Logan.Lyu@myais.com.cn>, "J . Dekker" <jdek@itanimul.li>
Subject: [FFmpeg-devel] [PATCH 06/21] aarch64: hevc: Implement a neon version of put_hevc_epel_h*_8
Date: Mon, 25 Mar 2024 17:02:28 +0200
Message-ID: <20240325150243.59058-7-martin@martin.st> (raw)
In-Reply-To: <20240325150243.59058-1-martin@martin.st>
AWS Graviton 3:
put_hevc_epel_h4_8_c: 64.7
put_hevc_epel_h4_8_neon: 25.0
put_hevc_epel_h4_8_i8mm: 21.2
put_hevc_epel_h6_8_c: 130.0
put_hevc_epel_h6_8_neon: 40.7
put_hevc_epel_h6_8_i8mm: 36.5
put_hevc_epel_h8_8_c: 209.0
put_hevc_epel_h8_8_neon: 45.2
put_hevc_epel_h8_8_i8mm: 41.2
put_hevc_epel_h12_8_c: 465.5
put_hevc_epel_h12_8_neon: 104.5
put_hevc_epel_h12_8_i8mm: 86.5
put_hevc_epel_h16_8_c: 830.7
put_hevc_epel_h16_8_neon: 134.2
put_hevc_epel_h16_8_i8mm: 114.0
put_hevc_epel_h24_8_c: 1844.7
put_hevc_epel_h24_8_neon: 282.2
put_hevc_epel_h24_8_i8mm: 277.2
put_hevc_epel_h32_8_c: 3227.5
put_hevc_epel_h32_8_neon: 501.5
put_hevc_epel_h32_8_i8mm: 396.0
put_hevc_epel_h48_8_c: 7229.2
put_hevc_epel_h48_8_neon: 1120.2
put_hevc_epel_h48_8_i8mm: 901.2
put_hevc_epel_h64_8_c: 12869.0
put_hevc_epel_h64_8_neon: 1999.2
put_hevc_epel_h64_8_i8mm: 1610.5
---
libavcodec/aarch64/hevcdsp_epel_neon.S | 194 +++++++++++++++++++++-
libavcodec/aarch64/hevcdsp_init_aarch64.c | 17 ++
2 files changed, 209 insertions(+), 2 deletions(-)
diff --git a/libavcodec/aarch64/hevcdsp_epel_neon.S b/libavcodec/aarch64/hevcdsp_epel_neon.S
index d3f0a26f79..419e83529a 100644
--- a/libavcodec/aarch64/hevcdsp_epel_neon.S
+++ b/libavcodec/aarch64/hevcdsp_epel_neon.S
@@ -1321,8 +1321,6 @@ function ff_hevc_put_hevc_epel_uni_v64_8_neon, export=1
ret
endfunc
-#if HAVE_I8MM
-ENABLE_I8MM
.macro EPEL_H_HEADER
movrel x5, epel_filters
@@ -1332,6 +1330,198 @@ ENABLE_I8MM
mov x10, #(MAX_PB_SIZE * 2)
.endm
+function ff_hevc_put_hevc_epel_h4_8_neon, export=1
+ EPEL_H_HEADER
+ sxtl v0.8h, v30.8b
+1: ld1 {v4.8b}, [x1], x2
+ subs w3, w3, #1 // height
+ uxtl v4.8h, v4.8b
+ ext v5.16b, v4.16b, v4.16b, #2
+ ext v6.16b, v4.16b, v4.16b, #4
+ ext v7.16b, v4.16b, v4.16b, #6
+ mul v16.4h, v4.4h, v0.h[0]
+ mla v16.4h, v5.4h, v0.h[1]
+ mla v16.4h, v6.4h, v0.h[2]
+ mla v16.4h, v7.4h, v0.h[3]
+ st1 {v16.4h}, [x0], x10
+ b.ne 1b
+ ret
+endfunc
+
+function ff_hevc_put_hevc_epel_h6_8_neon, export=1
+ EPEL_H_HEADER
+ sxtl v0.8h, v30.8b
+ add x6, x0, #8
+1: ld1 {v3.16b}, [x1], x2
+ subs w3, w3, #1 // height
+ uxtl2 v4.8h, v3.16b
+ uxtl v3.8h, v3.8b
+ ext v5.16b, v3.16b, v4.16b, #2
+ ext v6.16b, v3.16b, v4.16b, #4
+ ext v7.16b, v3.16b, v4.16b, #6
+ mul v16.8h, v3.8h, v0.h[0]
+ mla v16.8h, v5.8h, v0.h[1]
+ mla v16.8h, v6.8h, v0.h[2]
+ mla v16.8h, v7.8h, v0.h[3]
+ st1 {v16.4h}, [x0], x10
+ st1 {v16.s}[2], [x6], x10
+ b.ne 1b
+ ret
+endfunc
+
+function ff_hevc_put_hevc_epel_h8_8_neon, export=1
+ EPEL_H_HEADER
+ sxtl v0.8h, v30.8b
+1: ld1 {v3.16b}, [x1], x2
+ subs w3, w3, #1 // height
+ uxtl2 v4.8h, v3.16b
+ uxtl v3.8h, v3.8b
+ ext v5.16b, v3.16b, v4.16b, #2
+ ext v6.16b, v3.16b, v4.16b, #4
+ ext v7.16b, v3.16b, v4.16b, #6
+ mul v16.8h, v3.8h, v0.h[0]
+ mla v16.8h, v5.8h, v0.h[1]
+ mla v16.8h, v6.8h, v0.h[2]
+ mla v16.8h, v7.8h, v0.h[3]
+ st1 {v16.8h}, [x0], x10
+ b.ne 1b
+ ret
+endfunc
+
+function ff_hevc_put_hevc_epel_h12_8_neon, export=1
+ EPEL_H_HEADER
+ add x6, x0, #16
+ sxtl v0.8h, v30.8b
+1: ld1 {v3.16b}, [x1], x2
+ subs w3, w3, #1 // height
+ uxtl2 v4.8h, v3.16b
+ uxtl v3.8h, v3.8b
+ ext v5.16b, v3.16b, v4.16b, #2
+ ext v6.16b, v3.16b, v4.16b, #4
+ ext v7.16b, v3.16b, v4.16b, #6
+ ext v20.16b, v4.16b, v4.16b, #2
+ ext v21.16b, v4.16b, v4.16b, #4
+ ext v22.16b, v4.16b, v4.16b, #6
+ mul v16.8h, v3.8h, v0.h[0]
+ mla v16.8h, v5.8h, v0.h[1]
+ mla v16.8h, v6.8h, v0.h[2]
+ mla v16.8h, v7.8h, v0.h[3]
+ mul v17.4h, v4.4h, v0.h[0]
+ mla v17.4h, v20.4h, v0.h[1]
+ mla v17.4h, v21.4h, v0.h[2]
+ mla v17.4h, v22.4h, v0.h[3]
+ st1 {v16.8h}, [x0], x10
+ st1 {v17.4h}, [x6], x10
+ b.ne 1b
+ ret
+endfunc
+
+function ff_hevc_put_hevc_epel_h16_8_neon, export=1
+ EPEL_H_HEADER
+ sxtl v0.8h, v30.8b
+1: ld1 {v1.8b, v2.8b, v3.8b}, [x1], x2
+ subs w3, w3, #1 // height
+ uxtl v1.8h, v1.8b
+ uxtl v2.8h, v2.8b
+ uxtl v3.8h, v3.8b
+ ext v5.16b, v1.16b, v2.16b, #2
+ ext v6.16b, v1.16b, v2.16b, #4
+ ext v7.16b, v1.16b, v2.16b, #6
+ ext v20.16b, v2.16b, v3.16b, #2
+ ext v21.16b, v2.16b, v3.16b, #4
+ ext v22.16b, v2.16b, v3.16b, #6
+ mul v16.8h, v1.8h, v0.h[0]
+ mla v16.8h, v5.8h, v0.h[1]
+ mla v16.8h, v6.8h, v0.h[2]
+ mla v16.8h, v7.8h, v0.h[3]
+ mul v17.8h, v2.8h, v0.h[0]
+ mla v17.8h, v20.8h, v0.h[1]
+ mla v17.8h, v21.8h, v0.h[2]
+ mla v17.8h, v22.8h, v0.h[3]
+ st1 {v16.8h, v17.8h}, [x0], x10
+ b.ne 1b
+ ret
+endfunc
+
+function ff_hevc_put_hevc_epel_h24_8_neon, export=1
+ EPEL_H_HEADER
+ sxtl v0.8h, v30.8b
+1: ld1 {v1.8b, v2.8b, v3.8b, v4.8b}, [x1], x2
+ subs w3, w3, #1 // height
+ uxtl v1.8h, v1.8b
+ uxtl v2.8h, v2.8b
+ uxtl v3.8h, v3.8b
+ uxtl v4.8h, v4.8b
+ ext v5.16b, v1.16b, v2.16b, #2
+ ext v6.16b, v1.16b, v2.16b, #4
+ ext v7.16b, v1.16b, v2.16b, #6
+ ext v20.16b, v2.16b, v3.16b, #2
+ ext v21.16b, v2.16b, v3.16b, #4
+ ext v22.16b, v2.16b, v3.16b, #6
+ ext v23.16b, v3.16b, v4.16b, #2
+ ext v24.16b, v3.16b, v4.16b, #4
+ ext v25.16b, v3.16b, v4.16b, #6
+ mul v16.8h, v1.8h, v0.h[0]
+ mla v16.8h, v5.8h, v0.h[1]
+ mla v16.8h, v6.8h, v0.h[2]
+ mla v16.8h, v7.8h, v0.h[3]
+ mul v17.8h, v2.8h, v0.h[0]
+ mla v17.8h, v20.8h, v0.h[1]
+ mla v17.8h, v21.8h, v0.h[2]
+ mla v17.8h, v22.8h, v0.h[3]
+ mul v18.8h, v3.8h, v0.h[0]
+ mla v18.8h, v23.8h, v0.h[1]
+ mla v18.8h, v24.8h, v0.h[2]
+ mla v18.8h, v25.8h, v0.h[3]
+ st1 {v16.8h, v17.8h, v18.8h}, [x0], x10
+ b.ne 1b
+ ret
+endfunc
+
+function ff_hevc_put_hevc_epel_h32_8_neon, export=1
+ EPEL_H_HEADER
+ ld1 {v1.8b}, [x1], #8
+ sub x2, x2, w6, uxtw // decrement src stride
+ mov w7, w6 // original width
+ sub x2, x2, #8 // decrement src stride
+ sub x10, x10, w6, uxtw #1 // decrement dst stride
+ sxtl v0.8h, v30.8b
+ uxtl v1.8h, v1.8b
+1: ld1 {v2.8b, v3.8b}, [x1], #16
+ subs w6, w6, #16 // width
+ uxtl v2.8h, v2.8b
+ uxtl v3.8h, v3.8b
+ ext v5.16b, v1.16b, v2.16b, #2
+ ext v6.16b, v1.16b, v2.16b, #4
+ ext v7.16b, v1.16b, v2.16b, #6
+ ext v20.16b, v2.16b, v3.16b, #2
+ ext v21.16b, v2.16b, v3.16b, #4
+ ext v22.16b, v2.16b, v3.16b, #6
+ mul v16.8h, v1.8h, v0.h[0]
+ mla v16.8h, v5.8h, v0.h[1]
+ mla v16.8h, v6.8h, v0.h[2]
+ mla v16.8h, v7.8h, v0.h[3]
+ mul v17.8h, v2.8h, v0.h[0]
+ mla v17.8h, v20.8h, v0.h[1]
+ mla v17.8h, v21.8h, v0.h[2]
+ mla v17.8h, v22.8h, v0.h[3]
+ st1 {v16.8h, v17.8h}, [x0], #32
+ mov v1.16b, v3.16b
+ b.gt 1b
+ subs w3, w3, #1 // height
+ add x1, x1, x2
+ b.le 9f
+ ld1 {v1.8b}, [x1], #8
+ mov w6, w7
+ add x0, x0, x10
+ uxtl v1.8h, v1.8b
+ b 1b
+9:
+ ret
+endfunc
+
+#if HAVE_I8MM
+ENABLE_I8MM
function ff_hevc_put_hevc_epel_h4_8_neon_i8mm, export=1
EPEL_H_HEADER
1: ld1 {v4.8b}, [x1], x2
diff --git a/libavcodec/aarch64/hevcdsp_init_aarch64.c b/libavcodec/aarch64/hevcdsp_init_aarch64.c
index 1e9f5e32db..ece911b8d4 100644
--- a/libavcodec/aarch64/hevcdsp_init_aarch64.c
+++ b/libavcodec/aarch64/hevcdsp_init_aarch64.c
@@ -223,6 +223,10 @@ NEON8_FNPROTO_PARTIAL_4(qpel_uni_w_v, (uint8_t *_dst, ptrdiff_t _dststride,
int height, int denom, int wx, int ox,
intptr_t mx, intptr_t my, int width),);
+NEON8_FNPROTO(epel_h, (int16_t *dst,
+ const uint8_t *_src, ptrdiff_t _srcstride,
+ int height, intptr_t mx, intptr_t my, int width),);
+
NEON8_FNPROTO(epel_h, (int16_t *dst,
const uint8_t *_src, ptrdiff_t _srcstride,
int height, intptr_t mx, intptr_t my, int width), _i8mm);
@@ -290,6 +294,17 @@ NEON8_FNPROTO(qpel_bi_hv, (uint8_t *dst, ptrdiff_t dststride,
member[8][v][h] = ff_hevc_put_hevc_##fn##48_8_neon##ext; \
member[9][v][h] = ff_hevc_put_hevc_##fn##64_8_neon##ext;
+#define NEON8_FNASSIGN_SHARED_32(member, v, h, fn, ext) \
+ member[1][v][h] = ff_hevc_put_hevc_##fn##4_8_neon##ext; \
+ member[2][v][h] = ff_hevc_put_hevc_##fn##6_8_neon##ext; \
+ member[3][v][h] = ff_hevc_put_hevc_##fn##8_8_neon##ext; \
+ member[4][v][h] = ff_hevc_put_hevc_##fn##12_8_neon##ext; \
+ member[5][v][h] = ff_hevc_put_hevc_##fn##16_8_neon##ext; \
+ member[6][v][h] = ff_hevc_put_hevc_##fn##24_8_neon##ext; \
+ member[7][v][h] = \
+ member[8][v][h] = \
+ member[9][v][h] = ff_hevc_put_hevc_##fn##32_8_neon##ext;
+
#define NEON8_FNASSIGN_PARTIAL_4(member, v, h, fn, ext) \
member[1][v][h] = ff_hevc_put_hevc_##fn##4_8_neon##ext; \
member[3][v][h] = ff_hevc_put_hevc_##fn##8_8_neon##ext; \
@@ -384,6 +399,8 @@ av_cold void ff_hevc_dsp_init_aarch64(HEVCDSPContext *c, const int bit_depth)
NEON8_FNASSIGN(c->put_hevc_epel_uni_w, 1, 0, epel_uni_w_v,);
NEON8_FNASSIGN_PARTIAL_4(c->put_hevc_qpel_uni_w, 1, 0, qpel_uni_w_v,);
+ NEON8_FNASSIGN_SHARED_32(c->put_hevc_epel, 0, 1, epel_h,);
+
if (have_i8mm(cpu_flags)) {
NEON8_FNASSIGN(c->put_hevc_epel, 0, 1, epel_h, _i8mm);
NEON8_FNASSIGN(c->put_hevc_epel, 1, 1, epel_hv, _i8mm);
--
2.39.3 (Apple Git-146)
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
next prev parent reply other threads:[~2024-03-25 15:04 UTC|newest]
Thread overview: 26+ messages / expand[flat|nested] mbox.gz Atom feed top
2024-03-25 15:02 [FFmpeg-devel] [PATCH 00/21] aarch64: hevc: Add missing hevc_pel NEON functions Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 01/21] aarch64: hevc: Reorder a misplaced function init line Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 02/21] aarch64: hevc: Don't iterate with sp in ff_hevc_put_hevc_qpel_uni_w_hv32/64_8_neon_i8mm Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 03/21] aarch64: hevc: Merge consecutive stores in put_hevc_\type\()_h16_8_neon Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 04/21] aarch64: hevc: Specialize put_hevc_\type\()_h*_8_neon for horizontal looping Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 05/21] aarch64: hevc: Use ld1r instead of ldr+dup in hevc_qpel_uni_w_h Martin Storsjö
2024-03-25 15:02 ` Martin Storsjö [this message]
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 07/21] aarch64: hevc: Implement a neon version of hevc_epel_uni_w_h*_8 Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 08/21] aarch64: hevc: Split the epel_*_hv functions into two parts Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 09/21] aarch64: hevc: Reorder epel_hv functions to prepare for templating Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 10/21] aarch64: hevc: Produce epel_hv functions for both plain neon and i8mm Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 11/21] aarch64: hevc: Produce epel_uni_hv functions for both " Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 12/21] aarch64: hevc: Produce epel_uni_w_hv " Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 13/21] aarch64: hevc: Produce epel_bi_hv " Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 14/21] aarch64: hevc: Implement a neon version of hevc_qpel_uni_w_h*_8 Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 15/21] aarch64: hevc: Split the qpel_*_hv functions into two parts Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 16/21] aarch64: hevc: Deduplicate the hevc_put_hevc_qpel_uni_w_hv*_8_end_neon functions Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 17/21] aarch64: hevc: Reorder qpel_hv functions to prepare for templating Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 18/21] aarch64: hevc: Produce plain neon versions of qpel_hv Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 19/21] aarch64: hevc: Produce plain neon versions of qpel_uni_hv Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 20/21] aarch64: hevc: Produce plain neon versions of qpel_uni_w_hv Martin Storsjö
2024-03-25 15:02 ` [FFmpeg-devel] [PATCH 21/21] aarch64: hevc: Produce plain neon versions of qpel_bi_hv Martin Storsjö
2024-03-25 21:15 ` [FFmpeg-devel] [PATCH 00/21] aarch64: hevc: Add missing hevc_pel NEON functions Martin Storsjö
2024-03-25 21:56 ` J. Dekker
2024-03-26 6:01 ` Jean-Baptiste Kempf
2024-03-26 7:09 ` Martin Storsjö
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20240325150243.59058-7-martin@martin.st \
--to=martin@martin.st \
--cc=Logan.Lyu@myais.com.cn \
--cc=ffmpeg-devel@ffmpeg.org \
--cc=jdek@itanimul.li \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Git Inbox Mirror of the ffmpeg-devel mailing list - see https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
This inbox may be cloned and mirrored by anyone:
git clone --mirror https://master.gitmailbox.com/ffmpegdev/0 ffmpegdev/git/0.git
# If you have public-inbox 1.1+ installed, you may
# initialize and index your mirror using the following commands:
public-inbox-init -V2 ffmpegdev ffmpegdev/ https://master.gitmailbox.com/ffmpegdev \
ffmpegdev@gitmailbox.com
public-inbox-index ffmpegdev
Example config snippet for mirrors.
AGPL code for this site: git clone https://public-inbox.org/public-inbox.git