[FFmpeg-devel] [PATCH 1/3] riscv: factor out the bswap32 assembler

[FFmpeg-devel] [PATCH 1/3] riscv: factor out the bswap32 assembler

[Rémi Denis-Courmont]

---
 libavcodec/riscv/bswapdsp_rvb.S | 43 +---------------------
 libavutil/riscv/bswap_rvb.S     | 65 +++++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+), 41 deletions(-)
 create mode 100644 libavutil/riscv/bswap_rvb.S

diff --git a/libavcodec/riscv/bswapdsp_rvb.S b/libavcodec/riscv/bswapdsp_rvb.S
index 91b47bf82d..0786bd3f36 100644
--- a/libavcodec/riscv/bswapdsp_rvb.S
+++ b/libavcodec/riscv/bswapdsp_rvb.S
@@ -20,49 +20,10 @@
 
 #include "config.h"
 #include "libavutil/riscv/asm.S"
+#include "libavutil/riscv/bswap_rvb.S"
 
 #if (__riscv_xlen >= 64)
 func ff_bswap32_buf_rvb, zbb
-        andi    t0, a1, 4
-        beqz    t0, 1f
-        /* Align a1 (input) to 64-bit */
-        lwu     t0, (a1)
-        addi    a0, a0, 4
-        rev8    t0, t0
-        addi    a2, a2, -1
-        srli    t0, t0, __riscv_xlen - 32
-        addi    a1, a1, 4
-        sw      t0, -4(a0)
-1:
-        andi    a3, a2, -2
-        sh2add  a2, a2, a0
-        beqz    a3, 3f
-        sh2add  a3, a3, a0
-2:      /* 2 elements (64 bits) at a time on a 64-bit boundary */
-        ld      t0,  (a1)
-        addi    a0, a0, 8
-        rev8    t0, t0
-#if (__riscv_xlen == 64)
-        srli    t2, t0, 32
-        sw      t0, -4(a0)
-#else
-        srli    t1, t0, __riscv_xlen - 64
-        srli    t2, t0, __riscv_xlen - 32
-        sw      t1, -4(a0)
-#endif
-        addi    a1, a1, 8
-        sw      t2, -8(a0)
-        bne     a0, a3, 2b
-3:
-        beq     a0, a2, 5f
-4:      /* Process last element */
-        lwu     t0, (a1)
-        addi    a0, a0, 4
-        rev8    t0, t0
-        addi    a1, a1, 4
-        srli    t0, t0, __riscv_xlen - 32
-        sw      t0, -4(a0)
-5:
-        ret
+        bswap32_rvb a0, a1, a2
 endfunc
 #endif
diff --git a/libavutil/riscv/bswap_rvb.S b/libavutil/riscv/bswap_rvb.S
new file mode 100644
index 0000000000..b391e2f9f1
--- /dev/null
+++ b/libavutil/riscv/bswap_rvb.S
@@ -0,0 +1,65 @@
+/*
+ * Copyright © 2022 Rémi Denis-Courmont.
+ *
+ * This file is part of FFmpeg.
+ *
+ * FFmpeg is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU Lesser General Public
+ * License as published by the Free Software Foundation; either
+ * version 2.1 of the License, or (at your option) any later version.
+ *
+ * FFmpeg is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+ * Lesser General Public License for more details.
+ *
+ * You should have received a copy of the GNU Lesser General Public
+ * License along with FFmpeg; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
+ */
+
+#if (__riscv_xlen >= 64)
+	.macro  bswap32_rvb out, in, count
+        andi    t0, \count, 4
+        beqz    t0, 1f
+        /* Align input to 64-bit */
+        lwu     t0, (\in)
+        addi    \out, \out, 4
+        rev8    t0, t0
+        addi    \count, \count, -1
+        srli    t0, t0, __riscv_xlen - 32
+        addi    \in, \in, 4
+        sw      t0, -4(\out)
+1:
+        andi    t3, \count, -2
+        sh2add  \count, \count, \out
+        beqz    t3, 3f
+        sh2add  t3, t3, \out
+2:      /* 2 elements (64 bits) at a time on a 64-bit boundary */
+        ld      t0,  (\in)
+        addi    \out, \out, 8
+        rev8    t0, t0
+#if (__riscv_xlen == 64)
+        srli    t2, t0, 32
+        sw      t0, -4(\out)
+#else
+        srli    t1, t0, __riscv_xlen - 64
+        srli    t2, t0, __riscv_xlen - 32
+        sw      t1, -4(\out)
+#endif
+        addi    \in, \in, 8
+        sw      t2, -8(\out)
+        bne     \out, t3, 2b
+3:
+        beq     \out, \count, 5f
+4:      /* Process last element */
+        lwu     t0, (\in)
+        addi    \out, \out, 4
+        rev8    t0, t0
+        addi    \in, \in, 4
+        srli    t0, t0, __riscv_xlen - 32
+        sw      t0, -4(\out)
+5:
+        ret
+        .endm
+#endif
-- 
2.40.1

_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel

To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".

[FFmpeg-devel] [PATCH 2/3] swscale/rgb2rgb: add R-V Zbb shuffle_bytes_3210

[Rémi Denis-Courmont]

---
 libswscale/riscv/Makefile      |  1 +
 libswscale/riscv/rgb2rgb.c     |  7 ++++++-
 libswscale/riscv/rgb2rgb_rvb.S | 30 ++++++++++++++++++++++++++++++
 3 files changed, 37 insertions(+), 1 deletion(-)
 create mode 100644 libswscale/riscv/rgb2rgb_rvb.S

diff --git a/libswscale/riscv/Makefile b/libswscale/riscv/Makefile
index 214d877b62..7b371d5a86 100644
--- a/libswscale/riscv/Makefile
+++ b/libswscale/riscv/Makefile
@@ -1,2 +1,3 @@
 OBJS += riscv/rgb2rgb.o
+OBJS += riscv/rgb2rgb_rvb.o
 RVV-OBJS += riscv/rgb2rgb_rvv.o
diff --git a/libswscale/riscv/rgb2rgb.c b/libswscale/riscv/rgb2rgb.c
index 4c2d0f07d2..21baaa21c5 100644
--- a/libswscale/riscv/rgb2rgb.c
+++ b/libswscale/riscv/rgb2rgb.c
@@ -29,6 +29,7 @@ void ff_shuffle_bytes_0321_rvv(const uint8_t *src, uint8_t *dst, int src_len);
 void ff_shuffle_bytes_2103_rvv(const uint8_t *src, uint8_t *dst, int src_len);
 void ff_shuffle_bytes_1230_rvv(const uint8_t *src, uint8_t *dst, int src_len);
 void ff_shuffle_bytes_3012_rvv(const uint8_t *src, uint8_t *dst, int src_len);
+void ff_shuffle_bytes_3210_rvb(const uint8_t *src, uint8_t *dst, int src_len);
 void ff_shuffle_bytes_3210_rvv(const uint8_t *src, uint8_t *dst, int src_len);
 void ff_interleave_bytes_rvv(const uint8_t *src1, const uint8_t *src2,
                              uint8_t *dst, int width, int height, int s1stride,
@@ -42,9 +43,13 @@ void ff_yuyvtoyuv422_rvv(uint8_t *ydst, uint8_t *udst, uint8_t *vdst,
 
 av_cold void rgb2rgb_init_riscv(void)
 {
-#if HAVE_RVV
     int flags = av_get_cpu_flags();
 
+#if (__riscv_xlen == 64)
+    if ((flags & AV_CPU_FLAG_RVB_BASIC) && (flags & AV_CPU_FLAG_RVB_ADDR))
+        shuffle_bytes_3210 = ff_shuffle_bytes_3210_rvb;
+#endif
+#if HAVE_RVV
     if ((flags & AV_CPU_FLAG_RVV_I32) && (flags & AV_CPU_FLAG_RVB_ADDR)) {
         shuffle_bytes_0321 = ff_shuffle_bytes_0321_rvv;
         shuffle_bytes_2103 = ff_shuffle_bytes_2103_rvv;
diff --git a/libswscale/riscv/rgb2rgb_rvb.S b/libswscale/riscv/rgb2rgb_rvb.S
new file mode 100644
index 0000000000..af127b32ed
--- /dev/null
+++ b/libswscale/riscv/rgb2rgb_rvb.S
@@ -0,0 +1,30 @@
+/*
+ * Copyright © 2022 Rémi Denis-Courmont.
+ *
+ * This file is part of FFmpeg.
+ *
+ * FFmpeg is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU Lesser General Public
+ * License as published by the Free Software Foundation; either
+ * version 2.1 of the License, or (at your option) any later version.
+ *
+ * FFmpeg is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+ * Lesser General Public License for more details.
+ *
+ * You should have received a copy of the GNU Lesser General Public
+ * License along with FFmpeg; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
+ */
+
+#include "config.h"
+#include "libavutil/riscv/asm.S"
+#include "libavutil/riscv/bswap_rvb.S"
+
+#if (__riscv_xlen >= 64)
+func ff_shuffle_bytes_3210_rvb, zbb
+        srli    a2, a2, 2
+        bswap32_rvb a1, a0, a2
+endfunc
+#endif
-- 
2.40.1

_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel

To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".

[FFmpeg-devel] [PATCH 3/3] swscale/rgb2rgb: remove R-V V shuffle_bytes_3012

[Rémi Denis-Courmont]

This is slower than the Zbb version on real hardware due to register
strides. Proper support for vector byte-swap requires the Zvbb
extension, but it's much too early for me to worry about it.
---
 libswscale/riscv/rgb2rgb.c     |  2 --
 libswscale/riscv/rgb2rgb_rvv.S | 25 -------------------------
 2 files changed, 27 deletions(-)

diff --git a/libswscale/riscv/rgb2rgb.c b/libswscale/riscv/rgb2rgb.c
index 21baaa21c5..162a4082b0 100644
--- a/libswscale/riscv/rgb2rgb.c
+++ b/libswscale/riscv/rgb2rgb.c
@@ -30,7 +30,6 @@ void ff_shuffle_bytes_2103_rvv(const uint8_t *src, uint8_t *dst, int src_len);
 void ff_shuffle_bytes_1230_rvv(const uint8_t *src, uint8_t *dst, int src_len);
 void ff_shuffle_bytes_3012_rvv(const uint8_t *src, uint8_t *dst, int src_len);
 void ff_shuffle_bytes_3210_rvb(const uint8_t *src, uint8_t *dst, int src_len);
-void ff_shuffle_bytes_3210_rvv(const uint8_t *src, uint8_t *dst, int src_len);
 void ff_interleave_bytes_rvv(const uint8_t *src1, const uint8_t *src2,
                              uint8_t *dst, int width, int height, int s1stride,
                              int s2stride, int dstride);
@@ -55,7 +54,6 @@ av_cold void rgb2rgb_init_riscv(void)
         shuffle_bytes_2103 = ff_shuffle_bytes_2103_rvv;
         shuffle_bytes_1230 = ff_shuffle_bytes_1230_rvv;
         shuffle_bytes_3012 = ff_shuffle_bytes_3012_rvv;
-        shuffle_bytes_3210 = ff_shuffle_bytes_3210_rvv;
         interleaveBytes = ff_interleave_bytes_rvv;
 #if (__riscv_xlen == 64)
         uyvytoyuv422 = ff_uyvytoyuv422_rvv;
diff --git a/libswscale/riscv/rgb2rgb_rvv.S b/libswscale/riscv/rgb2rgb_rvv.S
index 0ac3afff7c..008f098bfe 100644
--- a/libswscale/riscv/rgb2rgb_rvv.S
+++ b/libswscale/riscv/rgb2rgb_rvv.S
@@ -74,31 +74,6 @@ func ff_shuffle_bytes_3012_rvv, zve32x
         ret
 endfunc
 
-func ff_shuffle_bytes_3210_rvv, zve32x
-        addi    t1, a0, 2
-        addi    t2, a0, 1
-        addi    t3, a0, 0
-        addi    a0, a0, 3
-        srai    a2, a2, 2
-        li      t4, 4
-1:
-        vsetvli    t0, a2, e8, m1, ta, ma
-        sub        a2, a2, t0
-        vlse8.v    v8, (a0), t4
-        sh2add     a0, t0, a0
-        vlse8.v    v9, (t1), t4
-        sh2add     t1, t0, t1
-        vlse8.v    v10, (t2), t4
-        sh2add     t2, t0, t2
-        vlse8.v    v11, (t3), t4
-        sh2add     t3, t0, t3
-        vsseg4e8.v v8, (a1)
-        sh2add     a1, t0, a1
-        bnez       a2, 1b
-
-        ret
-endfunc
-
 func ff_interleave_bytes_rvv, zve32x
 1:
         mv      t0, a0
-- 
2.40.1

_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel

To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".