From: "J. Dekker" <jdek@itanimul.li>
To: ffmpeg-devel@ffmpeg.org
Subject: [FFmpeg-devel] [PATCH v3] lavc/aarch64: hevc_add_res add 12bit variants
Date: Tue, 16 Aug 2022 14:12:06 +0200
Message-ID: <20220816121206.18448-1-jdek@itanimul.li> (raw)
In-Reply-To: <1d56db3e-e76b-7472-47-5b7ce1f0aac2@martin.st>
hevc_add_res_4x4_12_c: 46.0
hevc_add_res_4x4_12_neon: 18.7
hevc_add_res_8x8_12_c: 194.7
hevc_add_res_8x8_12_neon: 25.2
hevc_add_res_16x16_12_c: 716.0
hevc_add_res_16x16_12_neon: 69.7
hevc_add_res_32x32_12_c: 3820.7
hevc_add_res_32x32_12_neon: 261.0
Signed-off-by: J. Dekker <jdek@itanimul.li>
---
libavcodec/aarch64/hevcdsp_idct_neon.S | 156 ++++++++++++----------
libavcodec/aarch64/hevcdsp_init_aarch64.c | 34 ++---
2 files changed, 105 insertions(+), 85 deletions(-)
diff --git a/libavcodec/aarch64/hevcdsp_idct_neon.S b/libavcodec/aarch64/hevcdsp_idct_neon.S
index 484eea8437..97c51e06e3 100644
--- a/libavcodec/aarch64/hevcdsp_idct_neon.S
+++ b/libavcodec/aarch64/hevcdsp_idct_neon.S
@@ -37,11 +37,11 @@ const trans, align=4
.short 31, 22, 13, 4
endconst
-.macro clip10 in1, in2, c1, c2
- smax \in1, \in1, \c1
- smax \in2, \in2, \c1
- smin \in1, \in1, \c2
- smin \in2, \in2, \c2
+.macro clip2 in1, in2, min, max
+ smax \in1, \in1, \min
+ smax \in2, \in2, \min
+ smin \in1, \in1, \max
+ smin \in2, \in2, \max
.endm
function ff_hevc_add_residual_4x4_8_neon, export=1
@@ -64,25 +64,6 @@ function ff_hevc_add_residual_4x4_8_neon, export=1
ret
endfunc
-function ff_hevc_add_residual_4x4_10_neon, export=1
- mov x12, x0
- ld1 {v0.8h-v1.8h}, [x1]
- ld1 {v2.d}[0], [x12], x2
- ld1 {v2.d}[1], [x12], x2
- ld1 {v3.d}[0], [x12], x2
- sqadd v0.8h, v0.8h, v2.8h
- ld1 {v3.d}[1], [x12], x2
- movi v4.8h, #0
- sqadd v1.8h, v1.8h, v3.8h
- mvni v5.8h, #0xFC, lsl #8 // movi #0x3FF
- clip10 v0.8h, v1.8h, v4.8h, v5.8h
- st1 {v0.d}[0], [x0], x2
- st1 {v0.d}[1], [x0], x2
- st1 {v1.d}[0], [x0], x2
- st1 {v1.d}[1], [x0], x2
- ret
-endfunc
-
function ff_hevc_add_residual_8x8_8_neon, export=1
add x12, x0, x2
add x2, x2, x2
@@ -103,25 +84,6 @@ function ff_hevc_add_residual_8x8_8_neon, export=1
ret
endfunc
-function ff_hevc_add_residual_8x8_10_neon, export=1
- add x12, x0, x2
- add x2, x2, x2
- mov x3, #8
- movi v4.8h, #0
- mvni v5.8h, #0xFC, lsl #8 // movi #0x3FF
-1: subs x3, x3, #2
- ld1 {v0.8h-v1.8h}, [x1], #32
- ld1 {v2.8h}, [x0]
- sqadd v0.8h, v0.8h, v2.8h
- ld1 {v3.8h}, [x12]
- sqadd v1.8h, v1.8h, v3.8h
- clip10 v0.8h, v1.8h, v4.8h, v5.8h
- st1 {v0.8h}, [x0], x2
- st1 {v1.8h}, [x12], x2
- bne 1b
- ret
-endfunc
-
function ff_hevc_add_residual_16x16_8_neon, export=1
mov x3, #16
add x12, x0, x2
@@ -148,28 +110,6 @@ function ff_hevc_add_residual_16x16_8_neon, export=1
ret
endfunc
-function ff_hevc_add_residual_16x16_10_neon, export=1
- mov x3, #16
- movi v20.8h, #0
- mvni v21.8h, #0xFC, lsl #8 // movi #0x3FF
- add x12, x0, x2
- add x2, x2, x2
-1: subs x3, x3, #2
- ld1 {v16.8h-v17.8h}, [x0]
- ld1 {v0.8h-v3.8h}, [x1], #64
- sqadd v0.8h, v0.8h, v16.8h
- ld1 {v18.8h-v19.8h}, [x12]
- sqadd v1.8h, v1.8h, v17.8h
- sqadd v2.8h, v2.8h, v18.8h
- sqadd v3.8h, v3.8h, v19.8h
- clip10 v0.8h, v1.8h, v20.8h, v21.8h
- clip10 v2.8h, v3.8h, v20.8h, v21.8h
- st1 {v0.8h-v1.8h}, [x0], x2
- st1 {v2.8h-v3.8h}, [x12], x2
- bne 1b
- ret
-endfunc
-
function ff_hevc_add_residual_32x32_8_neon, export=1
add x12, x0, x2
add x2, x2, x2
@@ -209,10 +149,88 @@ function ff_hevc_add_residual_32x32_8_neon, export=1
ret
endfunc
-function ff_hevc_add_residual_32x32_10_neon, export=1
+.macro add_res bitdepth
+function ff_hevc_add_residual_4x4_\bitdepth\()_neon, export=1
+ mvni v21.8h, #((0xFF << (\bitdepth - 8)) & 0xFF), lsl #8
+ b hevc_add_residual_4x4_16_neon
+endfunc
+function ff_hevc_add_residual_8x8_\bitdepth\()_neon, export=1
+ mvni v21.8h, #((0xFF << (\bitdepth - 8)) & 0xFF), lsl #8
+ b hevc_add_residual_8x8_16_neon
+endfunc
+function ff_hevc_add_residual_16x16_\bitdepth\()_neon, export=1
+ mvni v21.8h, #((0xFF << (\bitdepth - 8)) & 0xFF), lsl #8
+ b hevc_add_residual_16x16_16_neon
+endfunc
+function ff_hevc_add_residual_32x32_\bitdepth\()_neon, export=1
+ mvni v21.8h, #((0xFF << (\bitdepth - 8)) & 0xFF), lsl #8
+ b hevc_add_residual_32x32_16_neon
+endfunc
+.endm
+
+add_res 10
+add_res 12
+
+function hevc_add_residual_4x4_16_neon, export=0
+ mov x12, x0
+ ld1 {v0.8h-v1.8h}, [x1]
+ ld1 {v2.d}[0], [x12], x2
+ ld1 {v2.d}[1], [x12], x2
+ ld1 {v3.d}[0], [x12], x2
+ sqadd v0.8h, v0.8h, v2.8h
+ ld1 {v3.d}[1], [x12], x2
+ movi v4.8h, #0
+ sqadd v1.8h, v1.8h, v3.8h
+ clip2 v0.8h, v1.8h, v4.8h, v21.8h
+ st1 {v0.d}[0], [x0], x2
+ st1 {v0.d}[1], [x0], x2
+ st1 {v1.d}[0], [x0], x2
+ st1 {v1.d}[1], [x0], x2
+ ret
+endfunc
+
+function hevc_add_residual_8x8_16_neon, export=0
+ add x12, x0, x2
+ add x2, x2, x2
+ mov x3, #8
+ movi v4.8h, #0
+1: subs x3, x3, #2
+ ld1 {v0.8h-v1.8h}, [x1], #32
+ ld1 {v2.8h}, [x0]
+ sqadd v0.8h, v0.8h, v2.8h
+ ld1 {v3.8h}, [x12]
+ sqadd v1.8h, v1.8h, v3.8h
+ clip2 v0.8h, v1.8h, v4.8h, v21.8h
+ st1 {v0.8h}, [x0], x2
+ st1 {v1.8h}, [x12], x2
+ bne 1b
+ ret
+endfunc
+
+function hevc_add_residual_16x16_16_neon, export=0
+ mov x3, #16
+ movi v20.8h, #0
+ add x12, x0, x2
+ add x2, x2, x2
+1: subs x3, x3, #2
+ ld1 {v16.8h-v17.8h}, [x0]
+ ld1 {v0.8h-v3.8h}, [x1], #64
+ sqadd v0.8h, v0.8h, v16.8h
+ ld1 {v18.8h-v19.8h}, [x12]
+ sqadd v1.8h, v1.8h, v17.8h
+ sqadd v2.8h, v2.8h, v18.8h
+ sqadd v3.8h, v3.8h, v19.8h
+ clip2 v0.8h, v1.8h, v20.8h, v21.8h
+ clip2 v2.8h, v3.8h, v20.8h, v21.8h
+ st1 {v0.8h-v1.8h}, [x0], x2
+ st1 {v2.8h-v3.8h}, [x12], x2
+ bne 1b
+ ret
+endfunc
+
+function hevc_add_residual_32x32_16_neon, export=0
mov x3, #32
movi v20.8h, #0
- mvni v21.8h, #0xFC, lsl #8 // movi #0x3FF
1: subs x3, x3, #1
ld1 {v0.8h -v3.8h}, [x1], #64
ld1 {v16.8h-v19.8h}, [x0]
@@ -220,8 +238,8 @@ function ff_hevc_add_residual_32x32_10_neon, export=1
sqadd v1.8h, v1.8h, v17.8h
sqadd v2.8h, v2.8h, v18.8h
sqadd v3.8h, v3.8h, v19.8h
- clip10 v0.8h, v1.8h, v20.8h, v21.8h
- clip10 v2.8h, v3.8h, v20.8h, v21.8h
+ clip2 v0.8h, v1.8h, v20.8h, v21.8h
+ clip2 v2.8h, v3.8h, v20.8h, v21.8h
st1 {v0.8h-v3.8h}, [x0], x2
bne 1b
ret
diff --git a/libavcodec/aarch64/hevcdsp_init_aarch64.c b/libavcodec/aarch64/hevcdsp_init_aarch64.c
index 9cbe983870..b6d5efb77f 100644
--- a/libavcodec/aarch64/hevcdsp_init_aarch64.c
+++ b/libavcodec/aarch64/hevcdsp_init_aarch64.c
@@ -25,22 +25,18 @@
#include "libavutil/aarch64/cpu.h"
#include "libavcodec/hevcdsp.h"
-void ff_hevc_add_residual_4x4_8_neon(uint8_t *_dst, const int16_t *coeffs,
- ptrdiff_t stride);
-void ff_hevc_add_residual_4x4_10_neon(uint8_t *_dst, const int16_t *coeffs,
- ptrdiff_t stride);
-void ff_hevc_add_residual_8x8_8_neon(uint8_t *_dst, const int16_t *coeffs,
- ptrdiff_t stride);
-void ff_hevc_add_residual_8x8_10_neon(uint8_t *_dst, const int16_t *coeffs,
- ptrdiff_t stride);
-void ff_hevc_add_residual_16x16_8_neon(uint8_t *_dst, const int16_t *coeffs,
- ptrdiff_t stride);
-void ff_hevc_add_residual_16x16_10_neon(uint8_t *_dst, const int16_t *coeffs,
- ptrdiff_t stride);
-void ff_hevc_add_residual_32x32_8_neon(uint8_t *_dst, const int16_t *coeffs,
- ptrdiff_t stride);
-void ff_hevc_add_residual_32x32_10_neon(uint8_t *_dst, const int16_t *coeffs,
- ptrdiff_t stride);
+void ff_hevc_add_residual_4x4_8_neon(uint8_t *_dst, const int16_t *coeffs, ptrdiff_t stride);
+void ff_hevc_add_residual_4x4_10_neon(uint8_t *_dst, const int16_t *coeffs, ptrdiff_t stride);
+void ff_hevc_add_residual_4x4_12_neon(uint8_t *_dst, const int16_t *coeffs, ptrdiff_t stride);
+void ff_hevc_add_residual_8x8_8_neon(uint8_t *_dst, const int16_t *coeffs, ptrdiff_t stride);
+void ff_hevc_add_residual_8x8_10_neon(uint8_t *_dst, const int16_t *coeffs, ptrdiff_t stride);
+void ff_hevc_add_residual_8x8_12_neon(uint8_t *_dst, const int16_t *coeffs, ptrdiff_t stride);
+void ff_hevc_add_residual_16x16_8_neon(uint8_t *_dst, const int16_t *coeffs, ptrdiff_t stride);
+void ff_hevc_add_residual_16x16_10_neon(uint8_t *_dst, const int16_t *coeffs, ptrdiff_t stride);
+void ff_hevc_add_residual_16x16_12_neon(uint8_t *_dst, const int16_t *coeffs, ptrdiff_t stride);
+void ff_hevc_add_residual_32x32_8_neon(uint8_t *_dst, const int16_t *coeffs, ptrdiff_t stride);
+void ff_hevc_add_residual_32x32_10_neon(uint8_t *_dst, const int16_t *coeffs, ptrdiff_t stride);
+void ff_hevc_add_residual_32x32_12_neon(uint8_t *_dst, const int16_t *coeffs, ptrdiff_t stride);
void ff_hevc_idct_8x8_8_neon(int16_t *coeffs, int col_limit);
void ff_hevc_idct_8x8_10_neon(int16_t *coeffs, int col_limit);
void ff_hevc_idct_16x16_8_neon(int16_t *coeffs, int col_limit);
@@ -100,4 +96,10 @@ av_cold void ff_hevc_dsp_init_aarch64(HEVCDSPContext *c, const int bit_depth)
c->idct_dc[2] = ff_hevc_idct_16x16_dc_10_neon;
c->idct_dc[3] = ff_hevc_idct_32x32_dc_10_neon;
}
+ if (bit_depth == 12) {
+ c->add_residual[0] = ff_hevc_add_residual_4x4_12_neon;
+ c->add_residual[1] = ff_hevc_add_residual_8x8_12_neon;
+ c->add_residual[2] = ff_hevc_add_residual_16x16_12_neon;
+ c->add_residual[3] = ff_hevc_add_residual_32x32_12_neon;
+ }
}
--
2.32.0 (Apple Git-132)
_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".
next prev parent reply other threads:[~2022-08-16 12:12 UTC|newest]
Thread overview: 12+ messages / expand[flat|nested] mbox.gz Atom feed top
2022-06-23 18:04 [FFmpeg-devel] [PATCH 1/3] checkasm/hevc_add_res: add 12bit test J. Dekker
2022-06-23 18:04 ` [FFmpeg-devel] [PATCH 2/3] lavc/aarch64: reformat add_res funcs J. Dekker
2022-08-09 11:04 ` Martin Storsjö
2022-06-23 18:04 ` [FFmpeg-devel] [PATCH 3/3] lavc/aarch64: hevc_add_res add 12bit variants J. Dekker
2022-08-09 11:13 ` Martin Storsjö
2022-08-09 11:21 ` Martin Storsjö
2022-08-16 5:01 ` [FFmpeg-devel] [PATCH v2] " J. Dekker
2022-08-16 11:38 ` Martin Storsjö
2022-08-16 12:12 ` J. Dekker [this message]
2022-08-16 12:46 ` [FFmpeg-devel] [PATCH v3] " Martin Storsjö
2022-08-18 13:07 ` J. Dekker
2022-08-09 11:02 ` [FFmpeg-devel] [PATCH 1/3] checkasm/hevc_add_res: add 12bit test Martin Storsjö
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20220816121206.18448-1-jdek@itanimul.li \
--to=jdek@itanimul.li \
--cc=ffmpeg-devel@ffmpeg.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Git Inbox Mirror of the ffmpeg-devel mailing list - see https://ffmpeg.org/mailman/listinfo/ffmpeg-devel
This inbox may be cloned and mirrored by anyone:
git clone --mirror https://master.gitmailbox.com/ffmpegdev/0 ffmpegdev/git/0.git
# If you have public-inbox 1.1+ installed, you may
# initialize and index your mirror using the following commands:
public-inbox-init -V2 ffmpegdev ffmpegdev/ https://master.gitmailbox.com/ffmpegdev \
ffmpegdev@gitmailbox.com
public-inbox-index ffmpegdev
Example config snippet for mirrors.
AGPL code for this site: git clone https://public-inbox.org/public-inbox.git