[FFmpeg-devel] [PATCH 1/5] lavc/aarch64: Add neon implementation for sse16

[Hubert Mazur <hum@semihalf.com>]

Provide neon implementation for sse16 function.

Performance comparison tests are shown below.
- sse_0_c: 273.0
- sse_0_neon: 48.2

Benchmarks and tests run with checkasm tool on AWS Graviton 3.

Signed-off-by: Hubert Mazur <hum@semihalf.com>
---
 libavcodec/aarch64/me_cmp_init_aarch64.c |  4 ++
 libavcodec/aarch64/me_cmp_neon.S         | 82 ++++++++++++++++++++++++
 2 files changed, 86 insertions(+)

diff --git a/libavcodec/aarch64/me_cmp_init_aarch64.c b/libavcodec/aarch64/me_cmp_init_aarch64.c
index 136b008eb7..3ff5767bd0 100644
--- a/libavcodec/aarch64/me_cmp_init_aarch64.c
+++ b/libavcodec/aarch64/me_cmp_init_aarch64.c
@@ -30,6 +30,9 @@ int ff_pix_abs16_xy2_neon(MpegEncContext *s, uint8_t *blk1, uint8_t *blk2,
 int ff_pix_abs16_x2_neon(MpegEncContext *v, uint8_t *pix1, uint8_t *pix2,
                       ptrdiff_t stride, int h);
 
+int sse16_neon(MpegEncContext *v, uint8_t *pix1, uint8_t *pix2,
+                  ptrdiff_t stride, int h);
+
 av_cold void ff_me_cmp_init_aarch64(MECmpContext *c, AVCodecContext *avctx)
 {
     int cpu_flags = av_get_cpu_flags();
@@ -40,5 +43,6 @@ av_cold void ff_me_cmp_init_aarch64(MECmpContext *c, AVCodecContext *avctx)
         c->pix_abs[0][3] = ff_pix_abs16_xy2_neon;
 
         c->sad[0] = ff_pix_abs16_neon;
+        c->sse[0] = sse16_neon;
     }
 }
diff --git a/libavcodec/aarch64/me_cmp_neon.S b/libavcodec/aarch64/me_cmp_neon.S
index e49d049fc2..88cd335443 100644
--- a/libavcodec/aarch64/me_cmp_neon.S
+++ b/libavcodec/aarch64/me_cmp_neon.S
@@ -278,3 +278,85 @@ function ff_pix_abs16_x2_neon, export=1
 
         ret
 endfunc
+
+function sse16_neon, export=1
+        // x0 - unused
+        // x1 - pix1
+        // x2 - pix2
+        // x3 - stride
+        // w4 - h
+
+        cmp             w4, #4
+        movi            d18, #0
+        b.lt            2f
+
+// make 4 iterations at once
+1:
+
+        // res = abs(pix1[0] - pix2[0])
+        // res * res
+
+        ld1             {v0.16b}, [x1], x3
+        ld1             {v1.16b}, [x2], x3
+        uabd            v30.16b, v0.16b, v1.16b
+        ld1             {v2.16b}, [x1], x3
+        umull           v29.8h, v30.8b, v30.8b
+        ld1             {v3.16b}, [x2], x3
+        umull2          v28.8h, v30.16b, v30.16b
+        uabd            v27.16b, v2.16b, v3.16b
+        uaddlp          v17.4s, v29.8h
+        umull           v26.8h, v27.8b, v27.8b
+        umull2          v25.8h, v27.16b, v27.16b
+        ld1             {v4.16b}, [x1], x3
+        uadalp          v17.4s, v26.8h
+        ld1             {v5.16b}, [x2], x3
+        uadalp          v17.4s, v25.8h
+        uabd            v24.16b, v4.16b, v5.16b
+        ld1             {v6.16b}, [x1], x3
+        umull           v23.8h, v24.8b, v24.8b
+        uadalp          v17.4s, v23.8h
+        umull2          v22.8h, v24.16b, v24.16b
+        uadalp          v17.4s, v22.8h
+        ld1             {v7.16b}, [x2], x3
+        uadalp          v17.4s, v28.8h
+        uabd            v21.16b, v6.16b, v7.16b
+        umull           v20.8h, v21.8b, v21.8b
+        uadalp          v17.4s, v20.8h
+        umull2          v19.8h, v21.16b, v21.16b
+        uadalp          v17.4s, v19.8h
+
+        sub             w4, w4, #4
+        uaddlv          d16, v17.4s
+        cmp             w4, #4
+        add             d18, d18, d16
+
+        b.ge            1b
+
+        cbnz            w4, 2f
+        fmov            w0, s18
+
+        ret
+
+// iterate by one
+2:
+
+        ld1             {v0.16b}, [x1], x3
+        ld1             {v1.16b}, [x2], x3
+
+        uabd            v30.16b, v0.16b, v1.16b
+        umull           v29.8h, v0.8b, v1.8b
+        umull2          v28.8h, v0.16b, v1.16b
+        uaddlp          v17.4s, v29.8h
+        uadalp          v17.4s, v28.8h
+
+
+        subs            w4, w4, #1
+        uaddlv          d16, v17.4s
+        add             d18, d18, d16
+
+        b.ne            2b
+        fmov            w0, s18
+
+        ret
+
+endfunc
-- 
2.34.1

_______________________________________________
ffmpeg-devel mailing list
ffmpeg-devel@ffmpeg.org
https://ffmpeg.org/mailman/listinfo/ffmpeg-devel

To unsubscribe, visit link above, or email
ffmpeg-devel-request@ffmpeg.org with subject "unsubscribe".